合并/合并两个表，删除新的重复项[SAS中的PROC SQL]

Question

similar questions have been asked on the forums but I seem to have a unique issue with mine. I'm not sure if this is because I don't have a unique ID or because my KEY is my actual data. I hope you guys can help.

I am trying to merge two tables (Old and New) that have identical column structures.

I want to retain all my values in the Old table and append ONLY new variables from New Table into a Combined Table. Any keys that exist in both tables should take on the value of the Old table.

OLD TABLE
Key | Points
AAA | 1
BBB | 2
CCC | 3

NEW TABLE
Key | Points
AAA | 2
BBB | 5
CCC | 8
DDD | 6

Combined TABLE
Key | Points
AAA | 1
BBB | 2
CCC | 3
DDD | 6

I feel like what I want to achieve is the venn diagram equivalent of this:

Venn diagram

... but for whatever reason I'm not getting the intended effect with this code:

CREATE TABLE Combined
SELECT * FROM Old as A
FULL OUTER JOIN New as B ON A.Key=B.Key
WHERE A.Key IS NULL OR B.Key IS NULL;

Answer 1

这可能对您有帮助。

SELECT B.[Key], MIN(CASE WHEN A.[Key] = B.[Key] THEN A.Points ELSE B.Points END) AS 'Points' FROM OldTable A CROSS APPLY NewTable B GROUP BY B.[Key]

Answer 2

As long as there are no duplicate values for key in either table:

SELECT COALESCE(a.key,b.key) AS key, COALESCE(a.points,b.points) AS points
  FROM old a FULL OUTER JOIN new b ON a.key EQ b.key

Coalesce returns the first value if the first value is not missing, and returns the second value otherwise.

Answer 3

If you don't have duplicate keys within either table, then a simple update statement in a data step will do the job. You just need to make sure that NEW_TABLE is the first in the list, so the values in OLD_TABLE will replace those where the key matches. Any keys unique to one table will be output automatically.

Your data needs to be sorted by Key, as in your example.

data OLD_TABLE;
input Key $ Points;
datalines;
AAA 1
BBB 2
CCC 3
;
run;

data NEW_TABLE;
input Key $ Points;
datalines;
AAA 2
BBB 5
CCC 8
DDD 6
;
run;

data want;
update new_table old_table;
by key;
run;

Answer 4

Order the datasets

proc sort data=old; 
    by key; 
run;
proc sort data=new; 
    by key; 
run;

Combine them with a data set with by, output only the first key if there is a match

data combined;
set 
    old
    new;
by key;
if first.key then output;
run;