Windows move命令未使用bat将匹配文件移动到目标文件夹

Question

I created a windows bat file which will create a directory and then create subdirectories finally it need to move the matching file to the destination folder but it is not moving showing error "A duplicate file name exists, or the file cannot be found" but I have the matching string in the folder. Please help on this

my batch script shows below

set AUTOMATEDDIR=C:/test/2122/Inter/Test/WEB

CD %AUTOMATEDDIR%\..\Reports\Deliverable
FOR %%d IN (AgentCreate) DO (
    MKDIR "%%d"
    FOR %%e IN (Requests Responses) DO (
    echo inside
        MKDIR "%%d\%%e"
        MOVE "Unidentified\%%e\*%%d*" "%%d\%%e"
    )
)

when I execute the above script it shows below error

C:\test\2122\Inter\Test\Reports\Deliverable>(
MKDIR "AgentCreate"
 FOR %e IN (Requests Responses) DO (
echo inside
 MKDIR "AgentCreate\%e"
 MOVE "Unidentified\%e\*AgentCreate*" "AgentCreate\%e"
)
)

C:\test\2122\Inter\Test\Reports\Deliverable>(
echo inside
 MKDIR "AgentCreate\Requests"
 MOVE "Unidentified\Requests\*AgentCreate*" "AgentCreate\Requests"
)
inside
A duplicate file name exists, or the file
cannot be found.

C:\test\2122\Inter\Test\Reports\Deliverable>(
echo inside
 MKDIR "AgentCreate\Responses"
 MOVE "Unidentified\Responses\*AgentCreate*" "AgentCreate\Responses"
)
inside
A duplicate file name exists, or the file
cannot be found.

My folder Requests contains folder "Res_20121203_Test_1" as below

 C:\test\2122\Inter\Test\Reports\Deliverable\Unidentified\Requests\Res_20121203_Test_1

Res_20121203_Test_1 folder contains files like below

-20121203B001601-292XtOHAAgentCreate601
-20121203B002603-292XtOHAAgentCreate603

The above files matching "AgentCreate" need to move "AgentCreate\\Requests" folder also matching files to "AgentCreate\\Responses"

Please help on this why it is not moving.

Answer 1

FOR %%d IN (AgentCreate) DO (
    MKDIR "%%d" 2>nul
    FOR %%e IN (Requests Responses) DO (
    echo inside
        MKDIR "%%d\%%e" 2>nul
        FOR /f "delims=" %%t IN ('dir /s /b /a-d "Unidentified\%%e\*%%d*" 2^>nul') do MOVE "%%t" "%%d\%%e" >nul
    )
)

I misread the requirement. This worked for me.

The 2>nul suppresses error messages. >nul suppresses "moved" reports and 2^>nul suppresses 'file not found' output of the dir . The caret is necessary to tell cmd that the redirection is part of the command to be executed, not part of the for .

Essetially, scan the trget directory for matching files /s in subdirectories /b in basic form (filename only) /ad and no directorynames.

You may want to try echo move to verify operation.

Please note that \\ is a directory-separator and / is a switch in winbatch. Some commands accept / as directory separators, but not all.