尝试使用Windows API从电子表格打开音频文件

Question

I am struggling to open sound files from Excel in a way that will not reveal their names (it's a quiz). I suspect this should be dead easy but everything I have seen so far confuses the hell out of me. I've built spreadsheet based quizzes before but not with sound files, I sort the order of the questions randomly and check my answers from values in hidden fields. Correct answers are summed – easy spreadsheet functions with a bit of VBA with dynamic ranges.

I just want to click on particular cells so that sound files open (from a file name in a hidden field a given offset from where I clicked), play a song and then close without revealing the file name , leaving me to type an answer in to the cell that caused the sound file to open.

I am using Windows 10 and Excel 2013 with a 64 bit computer.
I want to access MP3 sounds from just an ordinary directory, specified by a link. I would use hyperlinks but: a) They introduce obnoxious “do you really think this link is safe” messages which people online have had mixed success dealing with – it involves fiddling with the registry and I'd rather not go there. These display the name of the sound file which gives the game away! b) Files open in other applications and give away the name of the file. It's a faff closing them down again – the quiz could be hundreds of calls. I thought about embedding files but that seems memory intensive - if each file can open and close from elsewhere then why stick them into a vast spreadsheet? Instead I am trying to open the sound file using sndPlaySound which I believe is the 64 bit function that should accomplish the goal. There are posts everywhere about how to do this but none of them make the blindest bit of sense to me. I tried to adapt the code from the URL below (for 32 bit – using the different sndPlaySound32) but to no avail. http://www.cpearson.com/excel/PlaySound.aspx The code associated with my spreadsheet is (so far) very simple and responds to a user clicking in the Answer column of the quiz, getting the name of a sound file from a hidden location (using an offset) and calling the sndPlaySound function using the hidden file name.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

'Declare my sound directory
Dim SoundDirectory As String
SoundDirectory = "C:\Users\Andrew\Desktop\Bird Sounds\"

'The file name comes from a hidden cell using an offset function
Dim File As String
File = ActiveCell.Offset(columnOffset:=1).Value

'Declare variable link to be derived from SoundDirectory and File     variables
Dim Link As String

'Used to see if the user has moved to a cell used to open a sound file (2nd column)
Dim MyColumn As Long
If ActiveCell.Column = 2 Then
Link = SoundDirectory & File

‘The next line my machine hates this - it tells me there is a missing  "=" sign.

'sndPlaySound (Link,0)
End If
End Sub 

In a module I declared the sndPlaySound method from the windows API, altering it from the original because I believe it's sndPlaySound not sndPlaySound32 that I need with 64 bit

Public Declare Function sndPlaySound _
    Lib "winmm.dll" _
    Alias "sndPlaySoundA" ( _
    ByVal lpszSoundName As String, _
    ByVal uFlags As Long) As Long

I would be very grateful for any advice :)

Answer 1

I'm guessing your specific problem is evidenced by your comment:

'The next line my machine hates this - it tells me there is a missing "=" sign.

That is due to the syntax in VBA, and doesn't have anything to do with the API call. If you wrap the parameters in parenthesis you are telling the compiler that you care about the return value. Since you obviously don't care about the return (your code discards it), you'd need the Call keyword in front of it to signal that it can be discarded (and you should also explicitly pass the 0 as a Long - even better is to use the API constant declaration for SND_SYNC from mmsystem.h ):

Call sndPlaySound(Link, 0&)

If you omit the parenthesis, it is implicit that the return value can be ignored and the compiler doesn't complain about a missing assignment:

sndPlaySound Link, 0&

I also have no idea why Pearson declares the function returning a Long - it actually returns a BOOL , so it's safe to declare it in VBA as a Boolean ...

Public Declare Function sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" ( _
    ByVal lpszSoundName As String, ByVal uFlags As Long) As Boolean

...or since you never use the return value, you can simply discard the return value by declaring it as a Sub :

Public Declare Sub sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" ( _
    ByVal lpszSoundName As String, ByVal uFlags As Long)

That said, per MSDN, sndPlaySound is only maintained for backward compatibility - you should be using PlaySound instead:

Option Explicit

#If VBA7 Then
    Public Declare PtrSafe Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
        (ByVal pszSound As String, ByVal hmod As Any, ByVal fdwSound As Long) _
        As Boolean
#Else
    Public Declare Function PlaySound Lib "winmm.dll" Alias "PlaySoundA" _
        (ByVal pszSound As String, ByVal hmod As Any, ByVal fdwSound As Long) _
        As Boolean
#End If

'fdwSound flag constants:
Public Const SND_SYNC = 0&
Public Const SND_ASYNC = 1&
Public Const SND_NODEFAULT = 2&
Public Const SND_MEMORY = 4&
Public Const SND_LOOP = 8&
Public Const SND_NOSTOP = 16&
Public Const SND_NOWAIT = &H2000&
Public Const SND_ALIAS = &H10000
Public Const SND_FILENAME = &H20000

Public Sub Example()
    Dim wave As String
    wave = Environ("SystemRoot") & "\Media\" & "chord.wav"
    If PlaySound(wave, 0&, SND_FILENAME Or SND_NODEFAULT) = False Then
        Debug.Print "File not found."
    End If
End Sub

Note: I doubt the PtrSafe declaration is required as the only pointer being passed is a String , which AFAIK gets handled automatically (please leave a comment if this isn't accurate). Note that hmod can be declared as Any because you'll always be passing it a 0& from VBA.

Answer 2

I was struggling to implement the advice you guys gave me (sorry, and I do hope that your attempts to educate me were useful to you!). I did however find a very simple work around, albeit not one that I understand entirely. The work around uses a hyperlink from a hidden cell.

http://spreadsheetpage.com/index.php/tip/playing_mp3_files_from_excel/

Depending on what your default media player is the title may be more or less obvious as a giveaway. My next stage is to build a macro to extract the file names from the directory into the hidden column and perhaps to extract the names of the species from metadata. The former is something I have accomplished before (by stealing code from talented people!). I will attach some files to dropbox and link it here when I have the thing working full but in the meantime here's my code:

'This function responds to a user clicking in the Answer column of the quiz, getting the name of a sound file from a hidden
'location and calling the sndPlaySound function using it
'Macro which will trigger if you place the cursor in the second row between the 2nd and nth rows as defined by where there is data
Private Sub Worksheet_SelectionChange(ByVal Target As Range)


'Find End Row, used to see if macro should run from cursor insertion event
Dim EndRow As Long

'Declare my directory
Dim SoundDirectory As String
SoundDirectory = "C:\Users\Andrew\Desktop\Bird Sounds\"

'File name will be derived from contents of a cell
Dim File As String

With ActiveSheet
EndRow = .Cells(.Rows.Count, "A").End(xlUp).Row
End With

'Exit the sub routine if it is not relevant to procede

If ActiveCell.Column <> 2 Or ActiveCell.Row = 1 Or ActiveCell.Row > EndRow Then
    Exit Sub
    End If

    'The file name comes from a hidden cell using an offset function

    File = ActiveCell.Offset(columnOffset:=1).Value

    'Built from SoundDirectory and File
    Dim Sound As String

    Sound = SoundDirectory & File

    Application.ScreenUpdating = True
    On Error Resume Next
   ActiveSheet.OLEObjects.Add(Filename:=Sound, Link:=False).Select
   If Err.Number <> 0 Then
     Application.ScreenUpdating = True
     MsgBox "Incorrect or missing hyperlink"
     Exit Sub
   End If
   Selection.Verb
   Selection.Delete

End Sub

End Sub