TScrollbox在C ++ Builder中使用鼠标滚轮滚动

Question

I have added a scroll box inside a tabsheet in my form. I am able to scroll the contents when i clicked scroll up and down button in scroll box. But i want to scroll the contents using mouse wheel up and down. I have tried the below code.

void __fastcall TForm1::ScrollBox1MouseWheelUp(TObject *Sender, TShiftState Shift,
      TPoint &MousePos, bool &Handled)
{
    Form1->ScrollBox1->VertScrollBar->Position -= 3;
}

void __fastcall TForm1::ScrollBox1MouseWheelDown(TObject *Sender, TShiftState Shift,
      TPoint &MousePos, bool &Handled)
{
    Form1->ScrollBox1->VertScrollBar->Position += 3;
}

But the scrolling is not happening and control does not come over here when i tried to debug it. How to do scrolling using mouse wheel in scroll box?

Answer 1

You could implement the MouseWheel event on the owner form, and then test for Control under mouse is a TScrollBox:

procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState; WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
var
  i: Integer;
  TheScrollBox: TScrollBox;
  Control: TWinControl;
begin
  Control := FindVCLWindow(Mouse.CursorPos);
  Handled := Control is TScrollBox;

  if not Handled then
    exit;

  TheScrollBox := Control as TScrollBox;

  for i := 1 to Mouse.WheelScrollLines do
    try
      if WheelDelta > 0 then
        TheScrollBox.Perform(WM_VSCROLL, SB_LINEUP, 0)
      else
        TheScrollBox.Perform(WM_VSCROLL, SB_LINEDOWN, 0);
    finally
      TheScrollBox.Perform(WM_VSCROLL, SB_ENDSCROLL, 0);
    end;
end;

Another and more generic approach would be to implement Application.OnMessage :

Add a TApplicationEvents component to you mainform and the implement a OnMessageEvent :

procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG; var Handled: Boolean);
var
  i, Count: Integer;
  Control: TWinControl;
begin
  if Msg.message <> WM_MOUSEWHEEL then
    exit;

  Control := FindVCLWindow(Mouse.CursorPos);
  Handled := Control <> nil;

  if not Handled then
    exit;

  Count := 1;
  if Smallint(loWord(Msg.wParam)) = MK_CONTROL then
    Count := 5;

  try
    for i := 1 to Count do
      if Smallint(HiWord(Msg.wParam)) > 0 then
        Control.Perform(WM_VSCROLL, SB_LINEUP, 0)
      else
        Control.Perform(WM_VSCROLL, SB_LINEDOWN, 0);
  finally
    Control.Perform(WM_VSCROLL, SB_ENDSCROLL, 0);
  end;
end;

PS: WPARAM and LPARAM is documented in the MSDN