在Windows环境中将输入从类似设备的键盘重定向到后台进程

Question

I use simple RFID reader device which connected to PC with usb cable and identified as keyboard like device. I want to read input from this device by my application but it is running in background ie other application is in focus. How can I redirect stdin to my application in windows 7 environment? I can't change focus to my application I can't make change in front application (eg catch stdin and send it to my application via pipe etc.) My application is written in C# but I can rewrite it to Java / C The PC runs Win 7 OS.

Thanks y

Answer 1

Here my solution:

I have connected a normal Keyboard and a Card Reader via USB to my computer.
Both devices write to the windows keyboard buffer.

I want to redirect the input of the Card Reader to another application or file and remove it from the keyboard buffer (so that this input will not show up in any editor).

What I know / Prerequisites:

• The input of the Card Reader only contains hexadecimal letters (0-9, AF) and is finished by a newline.
• The Card Reader input will be received "on-block", this means between two received letters there are only a few milliseconds
• It is not possible for a human to enter two or more numbers within less than 70ms
  (I have tried it)

What I do:

• I listen to the keyboard buffer and take out every single input letter/key. Any input which is not 0-9 or AF will be put back to the keyboard buffer immediately.
• If a input 0-9 or AF comes up I will store it in a string buffer (it might be from the card reader)
• If there is no further input for more than 70ms and there are at least 4 Bytes containing 0-9 or AF in the buffer, then I assume/know it was from the Card Reader and use it in my own way. These Bytes have been already taken out of the keyboard buffer.
• If there are only one/two/three letter(s) 0-9/AF in my buffer, then after 70ms they will be put back to the windows keyboard buffer. While typing you can't realise that "some" letters show up a little postponed for a human being.

Here my program (written in the script language AutoHotkey ):

KeybRedir.ahk

; KeybRedir
; Programmiert von Michael Hutter - Mai 2018

#NoEnv ;Avoids checking empty variables to see if they are environment variables
#SingleInstance force
Process, Priority, , Normal
#Warn All

SaveKeyList=

0::
1::
2::
3::
4::
5::
6::
7::
8::
9::
+A::
+B::
+C::
+D::
+E::
+F::
Return::
{ ; If one of these characters was typed => take it out of windows key buffer...
    if A_ThisHotkey = Return
        Hotkey:=Chr(13)
    else
        Hotkey:=A_ThisHotkey
    SaveKeyList = %SaveKeyList%%Hotkey%
    SetTimer , DoKeyPlay, 70 ; Wait 70ms for another key press of charlist (re-trigger the timer in case it already runs)
}
return

DoKeyPlay:
    SetTimer , , Off
    SaveText:=RegExReplace(SaveKeyList, "\+", "")
    StringReplace, SaveText, SaveText, `r, , All
    if StrLen(SaveText) < 4 ; Accumulated text size < 4 letters => normal key input
    {
        SendPlay %SaveKeyList% ; put captured text back in windows key buffer
    }
    else ; Now we have the input of the card reader
    {
        SplashTextOn, , , %SaveText% ; Do something with the input or the card reader ...
    }
    SaveKeyList=
    SaveText=
    SetTimer , SplashOff, 2000
return

SplashOff:
    SplashTextOff
    SetTimer , , Off
return

You can compile this script to a exe file (327KB) using the Autohotkey Compiler .