换能器如何在core.async通道中执行？

Question

When making a channel a channel like so:

(chan 10 tx)

If i created 10 channels like this and then sent a message to all at the same time, how would the transducers be executed. Would they run concurrent or on one thread?

Answer 1

I think that right now the behaviour of when the transducer is run is not defined, but looking at the implementation of ManyToManyChannel , the transducer (which is the add! field) can be called both when writing and reading from the channel.

Running a simple test seems that if the channel is not full, the writing thread will execute the transducer, but if the channel is full, sometimes the reading thread runs it.

A sample with a small buffer:

(defn thread-name []
  (.getName (Thread/currentThread)))

(require '[clojure.core.async :as async :refer [chan <! >! >!! go]])

(defn p [& args]
  (locking *out*
          (apply println (thread-name) ":" args)))

(defn log [v]
  (p "Transforming" v)
  v)

(def tx (map log))

(def c (chan 1 tx))
(def c2 (chan 1 tx))

(go
  (loop []
    (when-let [v (<! c)]
      (p "Getting from c1" v)
      (<! (async/timeout 100))
      (recur))))

(go
  (loop []
    (when-let [v (<! c2)]
      (p "Getting from c2" v)
      (<! (async/timeout 100))
      (recur))))

(dotimes [_ 5]
  (p "Putting in c1" 1)
  (>!! c 1)
  (p "Putting in c2" 100)
  (>!! c2 100))

Produces the output:

nREPL-worker-20 : Transforming 1
nREPL-worker-20 : Putting in c2 100
async-dispatch-33 : Getting from c1 1
nREPL-worker-20 : Transforming 100
nREPL-worker-20 : Putting in c1 1
async-dispatch-31 : Getting from c2 100
nREPL-worker-20 : Transforming 1
nREPL-worker-20 : Putting in c2 100
nREPL-worker-20 : Transforming 100
nREPL-worker-20 : Putting in c1 1
async-dispatch-35 : Getting from c2 100
async-dispatch-34 : Transforming 1 <---- In this case is run in the reading side
async-dispatch-34 : Getting from c1 1
nREPL-worker-20 : Putting in c2 100
nREPL-worker-20 : Transforming 100
async-dispatch-37 : Getting from c2 100
async-dispatch-36 : Getting from c1 1
nREPL-worker-20 : Putting in c1 1