使用sed命令查找和替换的shell脚本

Question

I am new to shell scripting and have a request to modify multiple files. I have the input as below

#this is line1 for file1@abc.com     
test line 2  
test line 3  
this is line4 for file1@ABC.com  
test line 5  
this is line6 for file1@Abc.COM

and need output like

#this is line1 for file1@abc.com   
test line 2  
test line 3   
##this is line4 for file1@ABC.com  
this is line4 for file1@XYZ.com  
test line 5   
##this is line6 for file1@Abc.COM  
this is line6 for file1@Xyz.COM

I tried the below command to do this changes and it changes only abc to xyz and other are not getting changed

sed '/^[^#].*@abc.com/ {h; s/^/##/; p; g; s/abc.com/xyz.com/;}'

Please help me to modify the script case-insentitive

Answer 1

You're asking how to do case insensitive matching and replacement.

There's no good and portable way of doing this with sed . You can instead use eg [Aa] to match either A or a :

sed '/^[^#].*@[Aa][Bb][Cc]\.[Cc][Oo][Mm]/ {
        h; s/^/##/; p; g; s/[Aa][Bb][Cc]\.[Cc][Oo][Mm]/xyz.com/;
     }'

You can rewrite this to a single substitution to save some bytes:

sed 's/^\([^#].*\)[Aa][Bb][Cc]\.[Cc][Oo][Mm]\(.*\)/##&\
\1xyz.com\2/'

However, if you're using GNU sed (and not eg OSX sed), then you can use the I flag to s :

sed 's/^\([^#].*\)abc\.com\(.*\)/##&\n\1xyz.com\2/I'  # GNU only