XSLT转换（语法帮助）

Question

I have the following XML file I would like to use XSLT to transform into a csv file: (revised)

<ns4:transaction xmlns:ns2="http://www.example.com/Ops" xmlns:ns4="http://www.example.com/Transaction" xmlns:ns3="http://www.example.com/vehicleDetail">
<sender>sending person</sender>
<receiver>receiving person</receiver>
<created>2016-12-31T00:00:00Z</created>
<messages>
    <ns3:vehicleDetail>
        <identifier>
            <vehicle>Benz</vehicle>
            <dayOfOrigin>2016-02-01</dayOfOrigin>
            <localDayOfOrigin>2016-02-01</localDayOfOrigin>
            <initialDayOfOrigin>2016-02-01</initialDayOfOrigin>
            <localInitialDayOfOrigin>2016-02-01</localInitialDayOfOrigin>
        </identifier>
        <vehicleModified>UPD</vehicleModified>
        <vehicleOperStatus>O</vehicleOperStatus>
        <trip modified="UPD">
            <tripNo>198866</tripNo>
        </trip>
        <trip modified="UPD">
            <tripNo>198865</tripNo>
         </trip>
    </ns3:vehicleDetail>
</messages>
</ns4:transaction>

My xslt looks something like this:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:ns2="http://www.example.com/Ops" xmlns:ns4="http://www.example.com/Transaction" xmlns:ns3="http://www.example.com/vehicleDetail">
<xsl:template match="ns4:transaction">
    <xsl:for-each select="messages/ns3:vehicleDetail/trip">
        <xsl:value-of select="../../../created" />
        <xsl:text>,</xsl:text>
        <xsl:value-of select="tripNo"/>
    </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

The CSV file output should look something to this:

2016-12-31T00:00:00Z,198866
2016-12-31T00:00:00Z,198865

I did try to figure this out using XSLT with generic namespace handling, but I didn't go very far. Are there any hints/tips on how to do so?

*updated to reflect closer to question.

Answer 1

With a well-formed input XML such as:

<zero xmlns:alpha="http://example.com/alpha">
    <one>
        <fruit>
            <apple>Red</apple>
        </fruit>
        <alpha:test>
            <alphaA>1</alphaA>
            <alphaB>2</alphaB>
        </alpha:test>
        <alpha:test>
            <alphaA>3</alphaA>
            <alphaB>4</alphaB>
        </alpha:test>
    </one>
    <one>
        <fruit>
            <apple>Blue</apple>
        </fruit>
        <alpha:test>
            <alphaA>5</alphaA>
            <alphaB>6</alphaB>
        </alpha:test>
        <alpha:test>
            <alphaA>7</alphaA>
            <alphaB>8</alphaB>
        </alpha:test>
    </one>
</zero>

this would be rather trivial:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns1="http://example.com/alpha">
<xsl:output method="text" encoding="UTF-8" />

<xsl:template match="/zero">
    <xsl:for-each select="one/ns1:test">
        <xsl:value-of select="../fruit/apple"/>
        <xsl:text>,</xsl:text>
        <xsl:for-each select="*">
            <xsl:value-of select="."/>
            <xsl:if test="position()!=last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

---

Edit:

To handle your revised input, your stylesheet should look like this:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns4="http://www.example.com/Transaction" 
xmlns:ns3="http://www.example.com/vehicleDetail">
<xsl:output method="text" encoding="UTF-8" />

<xsl:template match="ns4:transaction">
    <xsl:for-each select="messages/ns3:vehicleDetail/trip">
        <xsl:value-of select="../../../created" />
        <xsl:text>,</xsl:text>
        <xsl:value-of select="tripNo"/>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Please note the added xmlns:xsl="http://www.w3.org/1999/XSL/Transform" declaration (without it a stylesheet is not a stylesheet) and the setting of the output method to text.