根据另一个哈希图集合更新哈希图集合值

Question

I have the following hash maps collection:

(def master-data [
    {:code "1234" :name "Jhon"}
    {:code "5678" :name "Brown"}
    {:code "9999" :name "Steven"}
])

and I have data in csv file with this information:

old_code,new_code,old_name,new_name
1234,2222,Jhon,Travolta
4321,3456,Steven,Cody

how can i change the values of inside master-data to the new data provide by the csv file?

the rules are:

1. if code inside master-data found in old_code column in csv file then change code value using new_code value from csv file.
2. if name inside master-data found in old_name column in csv file then change name value using new_name value from csv file.

Answer 1

you need to map your master data, checking every item from csv and updating master data entry if needed.

(defn update-if [item key check new-val]
  "utility function. updates a value for a key, setting it to new-val if it equals check"
  (if (= (item key) check)
    (assoc item key new-val)
    item))

(defn update-data [data mappings]
  (map (fn [item]
         (reduce (fn [item [old-code new-code old-name new-name]]
                   (-> item
                       (update-if :code old-code new-code)
                       (update-if :name old-name new-name)))
                 item
                 mappings))
       data))

in repl:

ttask.core> (def master-data [{:code "1234" :name "Jhon"}
                              {:code "5678" :name "Brown"}
                              {:code "9999" :name "Steven"}])
#'ttask.core/master-data

ttask.core> (def input "old_code,new_code,old_name,new_name
1234,2222,Jhon,Travolta
4321,3456,Steven,Cody")
#'ttask.core/input

ttask.core> (update-data master-data (rest (csv/read-csv input)))
({:code "2222", :name "Travolta"} {:code "5678", :name "Brown"} {:code "9999", :name "Cody"})