如何在复杂的 excel 公式中添加注释

Question

Is it possible to add a comment within the cell of an excel formula? I have an exceedingly long expression inside a cell that could better understood if I can comment within it.

Excel 2010 is my version. Here is an example cell I'd like to notate:

=MID(
A4,
((FIND("n   ",A4,FIND(G4,A4))+75)+LEN(H4)+78),
(FIND("n   ",A4,(FIND("n   ",A4,FIND(G4,A4))+75))) - ((FIND("n   ",A4,FIND(G4,A4))+78))
)

Answer 1

Like this:

=SUM(A1:A4)+N("This is a comment")

http://www.howtogeek.com/162231/add-comments-to-formulas-and-cells-in-excel-2013/

Answer 2

The N() function allows you add comments directly inside your cells on your formulas. To use the function to add a comment, simply add a plus sign (+) to the end of your formula, and then enter some text in quotes inside the parentheses, passing that text to the N() function.

Example: =YourFormula+N("comment")

Or you can use "add comment" in the Comments section of the Review tab. http://www.howtogeek.com/162231/add-comments-to-formulas-and-cells-in-excel-2013/

Answer 3

For the problem Tom Sharpe mentions in the Answer by Ben Rhys-Lewis, there is a solution. Well, being Excel, probably five or six, but:

For text functions you wish to append a comment to, use something like this:

=CONCATENATE(IFERROR(A1/A2,""),T(N("comment")))

N() will return a "0" which T() will then make into an Excel blank. It acts like "" in a formula in that it adds nothing to or into a string though it will not be a null if you paste values with it... an Excel "blank" is born.

Note that it works with the math if the division does not result in an error because while Excel makes text out fo the result, in the cell, it uses it as a number for math done on that cell's text-number result (for instance, a text "3.5" will still add to a numerical 9.5 in another cell tha that adds 6 to the "3.5" in the cell).

Also, to make the comments stand out, you can break the piece of your formula with Alt-Enter right before and right after that piece and its comment. Not like real commenting, but standing out more than some horrid muddle that it just increased stands out, enough worth doing and you can almost always add spaces before the comment as well:

=function stuff function stuff
CONCATENATE(IFERROR(A1/A2,""),    T(N("comment")))
and a bit more function stuff and more and more and so on...

Answer 4

The N() comment function does not have to be the last portion of the function. So this is a workable solution:

=+C6+N("description of C6 variable") +C7+N("C7 info") +C8+N("C8 info")

While not required, for improved readability I use params to indicate the comment refers to several elements. For this example the first comment just refers to "q13" cell while the next two comments refer to the calculation between the "(...)"

=+AA435 * q13+N(bonus multiplier) +(c435*$d$4/a435)+N("profit scaled by area") +(p24*$q$5 + w12*3)+N("blah...")

I always prefer to break up long complex formulas into a single simple consolidation formula that adds together hidden columns of intermediate formulas.

Answer 5

The LET function that was released in 2020 (available to Microsoft 365 subscribers) makes it possible to rewrite complex formulas in a more readable way by using variables. As Jim Pearson points out in his answer , you can also include comments as variables that are not used in the formula.

Here is one of many ways you could rewrite your formula with variable names that help understand the different parts of the formula:

=LET(\0, "Extract characters from text based on the contents of the other columns.",
     text, A4,
     find_string_G, FIND(G4, text),
     find_string_n, FIND("n   ", text, find_string_G),
     start_num, (find_string_n+75) + LEN(H4) + 78,
     num_chars, FIND("n   ", text, (find_string_n+75)) - (find_string_n+78),
MID(text, start_num, num_chars)
)

Answer 6

You could use the LET function like this:

=LET(
comment, "my comment",
SUM(P4:P10))