在perl中将字符串拆分为数组的哈希

Question

I have a string that looks like

This is sentence one.%%%0.3%%%0.6%%%This is sentence two.%%%0.4%%%0.9%%%

etc. The percent signs just act as delimiters and I can change them as need be.

I need to end up with something like this:

{
    'This is sentence one' => [0.3, 0.6],
    'This is sentence two' => [0.4, 0.9]
}

I can split it into an array or hash no problem, the only bit that's giving me trouble is making every first segment a key and every other segment an element of an array. Knowing perl, there's probably a very efficient way to do this in one line!

Answer 1

You will need to split the data into an array and pull items off three at a time, using the first of the three for a key and the remainder in an array reference

Like this

use strict;
use warnings 'all';

use Data::Dump;

my $str = 'This is sentence one.%%%0.3%%%0.6%%%This is sentence two.%%%0.4%%%0.9%%%';

my %data;

{
    my @data = split /%%%/, $str;

    while ( @data >= 3) {
        my @item = splice @data, 0, 3;
        $data{ shift @item } = \@item;
    }
}

dd \%data;

output

{
  "This is sentence one." => [0.3, 0.6],
  "This is sentence two." => [0.4, 0.9],
}