xslt 1.0转换结构问题

Question

The result I want is:

For each //root/document/ins/@contractId that has a match with //root/document/DetailGroup/Detail/Order/contract/@contractId , and the DetailSubtype is gross, order type=Surrender .

The transaction information should be summed up. The amount needed to be summed up should ONLY be full_sur and partial_sur , all else is to be ignored

And they want a specific structure, once for each matching logic.

First the xml file that needs to be transformed:

    <Document>
        <ins contractId="670">
          <Role>
             <person personId="60"/>
             <role>INS</role>
          </Role>
        </ins>
        <ins contractId="477">
          <Role>
             <person personId="60"/>
             <role>OWN</role>
          </Role>
        </ins>
       <DetailGroup>
            <Detail type="detailgross" DetailId="25">
                 <DetailSubtype>GROSS</DetailSubtype>
                 <Order type="Surrender">
                    <contract contractId="477"/>
                    <Transaction>
                       <Transaction>
                          <completedAmount>1443.08</completedAmount>
                          <TransactionSubtype>yield</TransactionSubtype>
                       </Transaction>
                      <Transaction>
                          <completedAmount>100.00</completedAmount>
                          <TransactionSubtype>fee</TransactionSubtype>
                       </Transaction>
                       <Transaction>
                          <completedAmount>200.00</completedAmount>
                          <TransactionSubtype>full_sur</TransactionSubtype>
                       </Transaction>
                    </Transaction>
                 </Order>
            </Detail>       

            <Detail type="detailgross" DetailId="24">
                 <DetailSubtype>gross</DetailSubtype>
                 <Order type="Surrender">
                    <contract contractId="670"/>
                    <Transaction>
                       <Transaction>
                          <completedAmount>1443.08</completedAmount>
                          <TransactionSubtype>fee</TransactionSubtype>
                       </Transaction>
                       <Transaction>
                          <completedAmount>100.00</completedAmount>
                          <TransactionSubtype>full_sur</TransactionSubtype>
                       </Transaction>
                       <Transaction>
                          <completedAmount>1000.00</completedAmount>
                          <TransactionSubtype>partial_sur</TransactionSubtype>
                       </Transaction>
                    </Transaction>
                 </Order>
            </Detail>

    </DetailGroup>
    </Document>

And then how they need it to look:

    <root>
        <document>
            <person role="INS" personId="60">
            </person>
            <bet>
                <spar>
                    <at sum="1100"/>
                </spar>
            </bet>
        </document>
        <document>
            <person role="OWN" personId="60">
            </person>
            <bet>
                <spar>
                    <at sum="200"/>
                </spar>
            </bet>
        </document>
    </root>

EDIT: I can only use xslt 1.0

<xsl:template name="example">
<xsl:variable name="detailId" select="//Document/DetailGrooup/Detail/Order/contract"/>
<xsl:for-each select="//Document/ins[@contractId=$detailId/@contractId]">
<document>
<person>
<xsl:attribute name="Role">
<xsl:value-of select="//Document/Role"/>
</xsl:attribute>
<xsl:attribute name="personId">
<xsl:value-of select="//Document/Role/Person/@PersonId"/>
</xsl:attribute>

</person>
<bet>
<spar>
<xsl:if test=".././DetailGrooup/Detail[DetailSubtype='GROSS' and ./Order/@type='Surrender' and /Order/Transaction/Transaction/TransactionSubtype='full_sur']">
<xsl:attribute name="at">
<xsl:value-of select="sum(//Document/DetailGrooup/Detail/Order[/contract/@contractId='@contractId']/Transaction/Transaction/completedAmount)"
</xsl:attribute>
</xsl:if>
</spar>
</bet>

</document>
</xsl:for-each>


</xsl:template>

Answer 1

try this one

<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <!-- use a key to match contractId attributes -->
    <xsl:key name="kContract" match="Order" use="contract/@contractId"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Document">
        <root>
            <xsl:apply-templates/>
        </root>
    </xsl:template>

    <xsl:template match="ins">
        <document>
            <person role="{descendant::role}" personId="{descendant::person/@personId}"/>
            <bet>
                <spar>
                    <at>
                        <xsl:attribute name="sum">
                            <xsl:value-of select="sum(key('kContract', @contractId)/descendant::completedAmount[parent::Transaction[TransactionSubtype = 'full_sur' or TransactionSubtype = 'partial_sur']])"/>
                        </xsl:attribute>
                    </at>
                </spar>
            </bet>
        </document>
    </xsl:template>

    <xsl:template match="DetailGroup"/>

</xsl:stylesheet>