使用sed替换不在行尾的开头的模式

Question

Let's say I have input:

/a/b/c/d/e/
/a/b/c/d/e
a/b/c/d/e/
a/b/c/d/e

I'd like to replace all / that are not at the edges with + so the output is:

/a+b+c+d+e/
/a+b+c+d+e
a+b+c+d+e/
a+b+c+d+e

I've tried this command:

sed -e "s#\(.\)/\(.\)#\1+\2#g"

which is close but not quite:

/a+b/c+d/e/
/a+b/c+d/e
a+b/c+d/e/
a+b/c+d/e

presumably because the \\(.\\) overlap between successive / characters.

I don't believe sed has a null match operator for beginning or end of line. So, how is this done?

Answer 1

You can translate all slashes to + and then replace + (at the beginning or at the end) with a slash:

sed 'y/\//+/;s/^+\|+$/\//g;'

or if the OR operator isn't available:

sed 'y/\//+/;s/^+/\//;s/+$/\//;'

better if you change the delimiter to avoid to escape all literal slashes:

sed 'y~/~+~;s~^+\|+$~/~g;'

or if the OR operator isn't available:

sed 'y~/~+~;s~^+~/~;s~+$~/~;'

(where ^ is an anchor for the start of the line and $ for the end)

---

Other way: you can protect the slashes you want to preserve using a placeholder:

sed 's~^/~{`%{~;s~/$~{`%{~;y~/~+~;s~{`%{~/~g;'

Answer 2

If you have perl you can use lookarounds for this:

perl -pe 's~(?<!^)/(?!$)~+~g' file

Output:

/a+b+c+d+e/
/a+b+c+d+e
a+b+c+d+e/
a+b+c+d+e

Otherwise you can use this sed with 2 substitutes:

sed -r 's~(.)/(.)~\1+\2~g; s~(.)/(.)~\1+\2~g' file

Or this sed with labeling and looping:

sed -r ':a;s|(.)/(.)|\1+\2|g;ta' file

Answer 3

Here is a sed command that gives your output:

sed -r 's=(.)/\b=\1+=g;' file

• usually / is uses as separator for the s command, but here we use =
• the / is matched where there is something ( . ) before it and and we are at a word boundary
• initially I tried (.)/(.) but that did not work:
  • The second dot was consumed and the next match would only start after it,
  • ie in x/y/< the second match would only see /z and not y/z
  • with \\b the first match does not consume the y and the second match sees y/

Answer 4

This is the common and extremely useful sed idiom for doing jobs like this:

$ sed 's:a:aA:g; s:^/\|/$:aB:g; s:/:+:g; s:aB:/:g; s:aA:a:g' file
/a+b+c+d+e/
/a+b+c+d+e
a+b+c+d+e/
a+b+c+d+e

The 1st sub changes all a s to aA . At that point there is no letter a in the input that is not followed by the letter A (we need to do this first to ensure that after our 2nd sub the only aB s in the input are as a result of that 2nd sub)

The 2nd sub changes all / s at the start or end of a line to aB . At that point the only aB s in the input are where there were originally / s at the start or end of the line.

The 3rd sub changes all remaining / s (ie those that were not at the start or end of the line) to + s.

The 4th sub restores the aB s back to the original front/end / s.

The 5th sub restores the aA s back to the original a s.

Answer 5

This might work for you (GNU sed):

sed ':a;s/\([^\/]\)\/\([^\/]\)/\1+\2/g;ta' file

Or visually easier:

sed -r ':a;s#([^/])/([^/])#\1+\2#g;ta' file

It is really the same regexp twice:

sed 's/\([^\/]\)\/\([^\/]\)/\1+\2/g;s/\([^\/]\)\/\([^\/]\)/\1+\2/g' file