转到范围并将具有特定值的单元格添加到新范围

Question

I'm bit new with vba in Excel. I'm trying to make a funtion to check a range for a specific text and add the cell containing the value to a new range. And return the new range.

I found a piece of code from brettdj on almost the same matter and alter it a bit for my situation.

The function look like:

Function Test(Testvalue As String, TargetRange As Range) As Range

  Dim rng2 As Range
  Dim c As Range

  For Each c In TargetRange
    If c.Text = Testvalue Then
        If Not rng2 Is Nothing Then
        ' Add the 2nd, 3rd, 4th etc cell to our new range, rng2
        ' this is the most common outcome so place it first in the IF test (faster coding)
            Set rng2 = Union(rng2, c)
        Else
        ' the first valid cell becomes rng2
            Set rng2 = c
        End If
    End If
    Next
  Set Test = rng2
End Function

But when I put this in use in excel, for example in =IsBlank(test(Apple;A1:A5)) it returns a #VALUE!.

Has somebody an idea how i can get this to work. Many thz in advance

Answer 1

Cell addresses are of the String type, not a Range type, so you can't return both from the function. User Defined Functions (UDFs) cannot return Range objects. What you can do is return the addresses of each cell:

Function Test(Testvalue As String, TargetRange As Range) As String
  Dim rng2 As String
  Dim c As Range

    For Each c In TargetRange
        If c.Text = Testvalue Then
            If rng2 <> vbNullString Then
                ' Add the 2nd, 3rd, 4th etc cell to our new range, rng2
                ' this is the most common outcome so place it first in the IF test (faster coding)
                rng2 = rng2 & "," & c.Address
            Else
                ' the first valid cell becomes rng2
                rng2 = c.Address
            End If
        End If
    Next
    Test = rng2
End Function

The output from this function is a comma-delimited list of cell addresses where the string was found. (B3 contains the formula, B2 shows what the formula in B3 looks like.)

To use this string of cell addresses, you'd have to create a different UDF (although a UDF cannot modify a different cell's contents or formatting):

Function test2(TestValue As String) As String
    Dim c As Range
    For Each c In Range(TestValue)
        MsgBox "The cell's address is: " & c.Address
    Next c
    test2 = "Last calculated on " & Now()
End Function

If you're trying to modify in any way the cells that contain the text "Apple", you should consider using a different approach.

Answer 2

additional variant to already provided

Function Test(Testvalue As String, TargetRange As Range) As String
  Dim d As Object: Set d = CreateObject("Scripting.Dictionary")
  Dim c As Range
  For Each c In TargetRange
    If c.Value2 = Testvalue Then d.Add c.Address(0, 0), ""
  Next
  Test = Join(d.keys, ","):  Set d = Nothing
End Function