我正在尝试在批处理文件中执行许多命令。 我需要对一批.tiff文件执行处理

Question

I'm trying to perform a sequence of commands in a batch file. I need to perform a process on a batch of .tiff files then move the output .tiff files to another location and perform another process on the original .tiff files. The code I am trying is below;

for %f in (*.tiff) do gdaldem_slope_batch.bat %~nf & move /-y "C:\Users\wmiller\Desktop\temp\*slope*.tiff" "C:\Users\wmiller\Desktop\trial" & for %f in (*.tiff) do gdaldem_hillshade_batch.bat %~nf & move /-y "C:\Users\wmiller\Desktop\temp\*hillshade*.tiff" "C:\Users\wmiller\Desktop\trial" 

My problem is that it does the first command on the first file and moves it to the new location it then runs through the second command on all the files in turn and moves them to the new location. It then performs the first command on the second file and subsequently tries to run through the second command on all files attempting to create duplicates of the files already there.

Any advice, this is my first attempt at programming (incase you can't tell) so be gentle.

Thanks

Answer 1

I need to perform a process on a batch of .tiff files then move the output .tiff files to another location and perform another process on the original .tiff files.

Here's how you want to group the commands then (also changed to %% batch file syntax):

for %%f in (*.tiff) do ( 
  call gdaldem_slope_batch.bat %%~nf 
  move /-y "C:\Users\wmiller\Desktop\temp\*slope*.tiff" "C:\Users\wmiller\Desktop\trial"
)
for %%f in (*.tiff) do (
  call gdaldem_hillshade_batch.bat %%~nf
  move /-y "C:\Users\wmiller\Desktop\temp\*hillshade*.tiff" "C:\Users\wmiller\Desktop\trial"
)

If you really wanted this on one line as in the question, though usually discouraged, that can be done by grouping the entire first for command as follows:

(for %%f in (*.tiff) do call gdaldem_slope_batch.bat %%~nf & move /-y "C:\Users\wmiller\Desktop\temp\*slope*.tiff" "C:\Users\wmiller\Desktop\trial") & for %%f in (*.tiff) do call gdaldem_hillshade_batch.bat %%~nf & move /-y "C:\Users\wmiller\Desktop\temp\*hillshade*.tiff" "C:\Users\wmiller\Desktop\trial"