合并并输出SAS中的选定数据

Question

I am trying to merge and output some dataset in SAS. The idea is very simple,

My data looks like:

Data1 (Target Data)

RIC       date           
VOD     03/02/2014         
BATS    03/02/2014         
...       ...             

Data2(Sample Data)

RIC       date           price
VOD     01/02/2014         50
VOD     03/02/2014         57
VOD     05/02/2014         64
VOD     06/02/2014         58
VOD     08/02/2014         64
VOD     10/02/2014         57
...       ...             ...
BATS    01/02/2014         70
BATS    03/02/2014         58
BATS    05/02/2014         67
BATS    06/02/2014         55
...       ...             ...

Now I need to merge Data1 with Data2 and only keep the Target data with a (-1, +1) trading day window . The final output will look like this:

RIC  Trading_day_window     date           price
VOD         -1            01/02/2014         50
VOD          0            03/02/2014         57
VOD         +1            05/02/2014         64
BATS        -1            01/02/2014         70
BATS         0            03/02/2014         58
BATS        +1            05/02/2014         67

I know I have to use merge here first. But how to only keep the Target data with a (-1, +1) trading day window?

I think I might use subquery here. Can anyone help me out ? Thanks !

Answer 1

Use a double DOW loop. In the first one find the record where the dates match. In the second one output the records you want.

Here is your sample data, properly sorted.

data data1 ;
  input RIC $ date ;
  informat date ddmmyy10.;
  format date yymmdd10.;
cards;
BATS 03/02/2014
VOD 03/02/2014
;;;;
data data2;
  input RIC $ date price ;
  informat date ddmmyy10.;
  format date yymmdd10.;
cards;
BATS 01/02/2014 70
BATS 03/02/2014 58
BATS 05/02/2014 67
BATS 06/02/2014 55
VOD 01/02/2014 50
VOD 03/02/2014 57
VOD 05/02/2014 64
VOD 06/02/2014 58
VOD 08/02/2014 64
VOD 10/02/2014 57
;;;;

Now just merge by RIC and DATE and find the matching records.

data want ;
  do trading_day=1 by 1 until (last.ric);
    merge data1 (in=in1) data2;
    by ric date;
    if in1 then baseday = trading_day;
  end;
  do trading_day=1 by 1 until (last.ric);
    merge data1 (in=in1) data2;
    by ric date;
    if baseday -1 <= trading_day <= baseday+1 then do;
         trading_day_window = trading_day-baseday;
         output;
    end;
  end;
run;
proc print; run;

Answer 2

您可以在数据步骤中使用保留语句。

Answer 3

A simple proc sql statement can do this, using the between statement in the join. I've coded +/- 2 days as that seems to be the case in your example data, you can obviously make adjustments to this to comply with whatever rule you use to calculate trading window.

data data1;
input RIC $ date :ddmmyy10.;
format date date9.;
datalines; 
VOD     03/02/2014
BATS    03/02/2014
;
run;

data data2;
input RIC $ date :ddmmyy10. price;
format date date9.;
datalines;
VOD     01/02/2014         50
VOD     03/02/2014         57
VOD     05/02/2014         64
VOD     06/02/2014         58
VOD     08/02/2014         64
VOD     10/02/2014         57
BATS    01/02/2014         70
BATS    03/02/2014         58
BATS    05/02/2014         67
BATS    06/02/2014         55
;
run;

proc sql;
create table want 
as select 
    b.ric,
    b.date-a.date as trading_day_window,
    b.date,
    b.price
from data1 as a
     inner join
     data2 as b
     on a.ric=b.ric 
     and b.date between a.date-2 and a.date+2;
quit;

Answer 4

You've got some good answers here, so you'll have to play with it to pick the most efficient.

I'm suspecting that your data1 is pretty small. If it is, then I think this will be pretty efficient code as it avoids the sorting and potential sql optimizer malarchy. Otherwise, the SQL solution seems the most practical to me.

proc sql noprint;
select count(*)
into :OBSCOUNT
from data1;
quit;

data want(drop=date_ref ric_ref);
set data2;
   do   i = 1 to &obscount.;
    set data1 (rename=(date=date_ref ric=ric_ref)) point=i;
    trading_day_window = (abs(date-date_ref)-1)*sign(date-date_ref);
    if ric=ric_ref
        and -1 <= trading_day_window <= 1
    then output;
   end;
run;