Perl：对多维散列中的值进行排序

Question

I have a subroutine that looks likes this:

...

sub UserLogins { 
  my %loginData; 
  my @logins = qx(last) or die;

  foreach my $row (@logins) {
    if ( $row=~ /^(\w+)\s+/ and (("$1" ne "reboot") and ("$1" ne "wtmp")) ) {
      $loginData{$1}{"logins"}++; 
    }
  }

return \%loginData
}

...

Using this subroutine in main script, I get following output:

...

$VAR1 = {
     'user1' => {
             'oldpassword' = 0,
             'filesize' => '14360',
             'logins' => 1
      },
      'user2' => {
             'oldpassword' = 0,
             'filesize' => '1220',
             'logins' => 15
      },
      'user3' => {
             'oldpassword' = 1,
             'filesize' => '1780',
             'logins' => 7
      }
}

...

I wonder how I should sort my %loginData hash so user with largest number of logins gets printed first (in this case user2, user3, user1).

I have also tried to sort values in this way:

foreach my $test_sort (sort {$a <=> $b} values %loginData) {
    say $test_sort;
}

But this function doesn't work at all.

Another thing I tried and didn't work:

print "$_\n" foreach sort {$loginData{$b}->{logins} <=> $loginData{$a}->{logins}} keys %loginData;

Update

This function actually works, but shows errors massages:

print "$_\n" foreach sort {$userData{$b}->{'logins'} <=> $userData{$a}->{'logins'}} keys %userData;

Errors:

Use of uninitialized values in numeric comparison (<=>)

Answer 1

Here's a canonical solution for accessing elements of a hash in some order based on an attribute of the value (in this case logins ):

for (sort { $loginData{$b}->{logins} <=>  $loginData{$a}->{logins} } keys %loginData)
{
    ... 
}

Note reversal of $b and $a to achieve a reverse sort (most logins first).

Answer 2

You can't sort a hash. From the Perl docs:

Hash entries are returned in an apparently random order.

You can, compute a list of keys that index the hash in the order you like.

Something like this:

use Data::Dumper;

our $hash = {
     'user1' => {
             'oldpassword' => 0,
             'filesize' => '14360',
             'logins' => 1
      },
      'user2' => {
             'oldpassword' => 0,
             'filesize' => '1220',
             'logins' => 15
      },
      'user3' => {
             'oldpassword' => 1,
             'filesize' => '1780',
             'logins' => 7
      }
};

sub KeysByLogins {
  my $hash = shift;
  map { $_->[1] }
  sort { $a->[0] <=> $b->[0] }
  map { [ $hash->{$_}->{logins}, $_ ] } keys %$hash;
}

foreach my $key (KeysByLogins($hash)) {
  print Data::Dumper->Dump([$hash->{$key}], [$key]) . "\n";
}

Then...

$ perl foo.pl

$user1 = {
           'filesize' => '14360',
           'oldpassword' => 0,
           'logins' => 1
         };

$user3 = {
           'logins' => 7,
           'oldpassword' => 1,
           'filesize' => '1780'
         };

$user2 = {
           'oldpassword' => 0,
           'filesize' => '1220',
           'logins' => 15
         };