读取一个单元格的值并提取其包含的数字

Question

The cells of a specific range contain information of the form Check. 3 months Check. 3 months or Dep. 2 months Dep. 2 months . I need embed vba so to read these cells and every time extract, that is output, the number that it is contained.

I know that there are functions when you know what you're searching for but for what I describe I am not aware of anything

Can you help please as I haven't encounter a similar task in the past.

Answer 1

You can loop through each character in the string and check to see if it is numeric. this will work for values 0-9. If there are values higher you would need to adjust this to look for multiple digits and not exit once the first one is found.

Public Function GetMyDigit(cell As Range) As Integer
Dim s As String
Dim i As Integer

'get cell value
s = cell.Value

'loop through the entire string
For i = 1 To Len(s)
    'check to see if the character is a numeric one
    If IsNumeric(Mid(s, i, 1)) = True Then
        'set the function to the value and exit
        GetMyDigit = Mid(s, i, 1)
        Exit Function
    End If
Next i
End Function

and if you have multiple digits

Public Function GetMyDigit(cell As Range)
Dim s As String
Dim i As Integer
Dim answer
'get cell value
s = cell.Value

'loop through the entire string
For i = 1 To Len(s)
    'check to see if the character is a numeric one
    If IsNumeric(Mid(s, i, 1)) = True Then
        'set the function to the value and exit
        answer = answer & Mid(s, i, 1)
    End If
Next i
 GetMyDigit = answer
End Function

Answer 2

Just to give another method:

Function findNumber(inPtStr As String) As Double
    Dim strArr() As String
    Dim i As Long
    strArr = Split(inPtStr)
    For i = LBound(strArr) To UBound(strArr)
        If IsNumeric(strArr(i)) Then
            findNumber = --strArr(i)
            Exit Function
        End If
    Next i
End Function