Prolog Predicate findall / 3和member / 2 Issue

Question

Basically, have a series of facts in my Knowledge base regarding PopStars and their most successful years (see below).

popStar('Jackson',1987,1991).
popStar('Jackson',1992,1996).
popStar('Michaels',1996,2000).
popStar('Newcastle',2000,2007).
popStar('Bowie',2008,2010).

I need to create a predicate that takes a single parameter that is true if the name of the popStar is recognized and, if a variable is used instead, it would produce backtracking, without any duplicates. Originally I started off with something very simple (see below).

  ispopStar ().
  ispopStar (H) :-  popStar (H,_,_).

But then figured out that any backtracking would include duplicates ('Jackson' mentioned twice). So, looking to create a list using findall/3 and then use member to check whether the popStar is a valid one.

However, whenever I attempt to use the member predicate on the list I've created from the facts, it would always result in an non-stopping, ever expanding list. I think it could well be a noob error as I've only just started learning prolog. Would really appreciate it if someone could take a look at my code below and could see what I'm doing wrong.

Thanks.

Findall/3

   findall(V,popStar(V,B,N),X)

Result

   X = ['Jackson', 'Jackson', 'Michaels', 'Newcastle', 'Bowie']

Member/2

   member('Newcastle',X).

Result

   339 ?- member('Newcastle',X).
   X = ['Newcastle'|_G2881] ;
   X = [_G2880, 'Newcastle'|_G2884] ;
   X = [_G2880, _G2883, 'Newcastle'|_G2887] ;
   X = [_G2880, _G2883, _G2886, 'Newcastle'|_G2890] ;
   X = [_G2880, _G2883, _G2886, _G2889, 'Newcastle'|_G2893]

Update

I've had a play around but still very stuck. I'm using the following predicate below to create a list of unique entries;

  setof(Name,X^Y^popStar(Name),Names)

And then using the following predicate for the existence of an element (example below).

 setof(Name,popStar(Name),Names), member('Jackson',Names). 

From the predicate above, it returns a value of;

 Names = ['Jackson'].

But really, I would expect it to return true, as 'member' certifies whether a specific elements is within a list. Also, when I try to insert a variable into member (so that it backtracks through all of the available popStars, I receive the following message).

setof(Name,popStar(Name),Names), member(X,Names).

Names = ['$VAR'('X')].

Would really appreciate some help by showing me what to do in this example. I'm really stuck so really appreciate it.

Answer 1

There are other more subtle problems with your approach, but first the obvious problem.

Queries on the top level do not share variables between each other. Each new query has new variables, even if they use the same name!

?- X = foo.
X = foo.

?- X = bar.
X = bar.

?- X = 3.
X = 3.

?- X == 3.
false.

You need to make a conjunction of subgoals!

?- L = [a,b,c,b], member(a, L).
L = [a, b, c, b] ;
false.

?- L = [a,b,c,b], member(b, L).
L = [a, b, c, b] ;
L = [a, b, c, b].

As you see, this is still not what you are after.... If a list has an element occurring twice, member/2 succeeds twice, and this is exactly what you don't want.

You could consider using memberchk/2 instead. If you compare the documentation on member/2 and memberchk/2 you should see how they differ in semantics and intended use. In short, if you already have a list that does not contain any variables, and you only want to check if that list contains a certain element, it is OK to use memberchk/2 :

?- L = [a,b,c,b], memberchk(a, L).
L = [a, b, c, b].

?- L = [a,b,c,b], memberchk(b, L).
L = [a, b, c, b].

This gets more hairy if any of the two arguments to memberchk/2 is not ground. Look at this:

?- memberchk(X, [a,b,c]).
X = a. % No more solutions!

So, this is not a good way to solve your problem.

It is maybe better to use setof/3 instead of findall/3 . To simplify a bit, say you have a table foo/1 that looks like the list from the example above:

?- listing(foo).

foo(a).
foo(b).
foo(c).
foo(b).

true.

?- findall(X, foo(X), Xs).
Xs = [a, b, c, b].

Then:

?- setof(X, foo(X), Xs), member(Y, Xs).
Xs = [a, b, c],
Y = a ;
Xs = [a, b, c],
Y = b ;
Xs = [a, b, c],
Y = c.

?- setof(X, foo(X), Xs), member(b, Xs).
Xs = [a, b, c] ;
false.

You would have to probably tell Prolog not to bind the second and third argument to pop_star/3 when you use setof/3 , so it would go something along the lines of setof(Name, X^Y^pop_star(Name, X, Y), Names) .