如何在Oracle 10g中使用成员

Question

I want to check if an element is a member of sys.odcinumberlist varray.

But it's not working...

What's wrong with my code?

DECLARE
  v_list sys.Odcinumberlist := sys.Odcinumberlist( 1, 2, 3, 4 );
BEGIN

  FOR i IN 1..v_list.COUNT LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;

  IF 1 MEMBER OF v_list THEN
    dbms_output.put_line( 'yes' );
  ELSE
    dbms_output.put_line( 'no' );    
  END IF;

END;

The error this code throws is

ORA-06550: line 9, column 6:
PLS-00306: wrong number or types of arguments in call to 'MEMBER OF'
ORA-06550: line 9, column 3:
PL/SQL: Statement ignored

Answer 1

SYS.Odcinumberlist is VARRAY and comparison of nested tables is not supported for VARRAYS. More info here --> https://docs.oracle.com/cd/B12037_01/appdev.101/b10799/adobjcol.htm
You can use SQL and the table function for this. See the example below

DECLARE
  v_list sys.Odcinumberlist := sys.Odcinumberlist( 1, 2, 3, 4 );
  v_member_found char(3);
BEGIN

  FOR i IN 1..v_list.COUNT LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;

  begin
   select 'yes' into v_member_found 
    from table(v_list) 
   where column_value = 1;
  exception
    when no_data_found 
     then v_member_found := 'no';
  end;
  dbms_output.put_line(v_member_found);

END;

Alternatively, you can loop over the collection

DECLARE
  v_list sys.Odcinumberlist := sys.Odcinumberlist( 1, 2, 3, 4 );
  v_member_found boolean := false;
BEGIN

  FOR i IN 1..v_list.COUNT LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;


  For i in 1..v_list.COUNT LOOP <<SearchLoop>>
    if v_list(i) = 1 then
       dbms_output.put_line('Member exists');
       v_member_found:=true;
       exit;
    end if;
  end Loop SearchLoop;

  if not v_member_found then
    dbms_output.put_line('member does not exist'); 
  end if;

END;

Answer 2

Since SYS.Odcinumberlist is a VARRAY and comparison is not supported. You can go with nested table type as describes below..

SET SERVEROUTPUT ON;
DECLARE
TYPE v_list_tab
IS
  TABLE OF NUMBER;
  v_list v_list_tab:=v_list_tab(1,2,3,4,5);
BEGIN
  FOR i IN 1..v_list.COUNT
  LOOP
    dbms_output.put_line( v_list(i) );
  END LOOP;
  IF 1 MEMBER OF v_list THEN
    dbms_output.put_line( 'yes' );
  ELSE
    dbms_output.put_line( 'no' );
  END IF;
END;