在运行时动态设置XML URI-XSLT选项

Question

I have a number of Java classes that I am using in conjunction with JAXB in order to generate XML. The java classes have minimal changes from year to year but the output XML needs to have very specific yearly changes to it and it's proving a little elusive. I've tried updating the attributes using DOM but nodes further along the tree are maintaining the previous state. I've tried using reflection to update the annotations directly before marshalling but it doesn't seem to be having the desired effect. I've also tried replacing the XMLRootElement object (and XMLType, XMLElement) with local classes but nothing seems to be working properly as some information always seems to be retained somewhere even when it seems that I have changed the member/attribute/etc.

I am not going to duplicate all the java objects on a yearly basis just so that I can change the namespaces to match the requirements.

Right now I'm at the point where I think XSLT might be the last option but I have little to no knowledge of it. Is there a simple way to update 5-8 namespace URI's that are located on the root element? I don't want to change the prefixes (they are already set using a prefix mapper), I just want to change the namespace from "com.help.me.2014" to "com.help.me.2015".

Thanks Andy

Resolution:

First off I greatly appreciate the effort and responses. I didn't actually try any of them as I came up with a different solution prior to getting back to see them.

Anyone coming along in the future can try the items listed below (as an XSLT solution) or you can try what I describe below.

I am generating XML in two different styles/formats, one with and one without SOAP wrappers. Due to my difficulty accessing the actual namespaces within the DOM/SOAP objects and my inability to alter the annotations at runtime I ended up capturing the output stream and manipulating the resulting string.

SOAP:

ByteArrayOutputStream stream = new ByteArrayOutputStream(); soapMessage.writeTo(stream); String file = new String(stream.toByteArray);

... manipulate file (now a string), replace values, etc. -> actually passed to dependency injected converters, then send on to client via response.write

JAXB Marshalling is very similar to the SOAP, both send the resulting String onto converters which manipulate it as a StringBuilder then send it on.

Thanks again for the suggestions. Hopefully it helps someone in the future although the requirement is a little out there.

Andy

Answer 1

Changing namespaces every year is almost certainly the wrong thing to do, but the following XSLT stylesheet will change namespaces

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:old="oldspace" 
    version="1.0">

    <xsl:template match="old:*">
        <xsl:element name="{local-name(.)}" namespace="newspace">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="@old:*">
        <xsl:attribute name="{local-name()}" namespace="newspace">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="*">
        <xsl:copy select=".">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:copy-of select="."/>
    </xsl:template>

    <xsl:template match="processing-instruction()|comment()">
        <xsl:copy-of select="."/>
    </xsl:template>

</xsl:stylesheet>

This style sheet creates a copy of every element changing the namespace from oldspace to newspace when appropriate. Other than the namespace change, the original document is preserved. Similar templates can be made for every namespace that needs to be changed (note there are two templates that are namespace specific).

Note that prefixes WILL be altered. These are not really content as such, so it is nearly impossible to preserve them in a case like this. The only way I can think of to preserve those would involve writing a separate template for each element in the original, directly creating the new elements instead of using the xsl:element element.

For example, the given xml

<os:myroot xmlns:os="oldspace">
    <?keep-this?>
    <os:testing abc='3' def='9'>
        <!-- This is a child -->
        <os:item>1234</os:item>
    </os:testing>
    <!-- this element is in the default namespace -->
    <testing2>
        <abc>112233</abc>
    </testing2>
</os:myroot>

is transformed to

<myroot xmlns="newspace">
    <?keep-this?>
    <testing>
        <!-- This is a child -->
        <item>1234</item>
    </testing>
    <!-- this element is in the default namespace -->
    <testing2 xmlns="">
        <abc>112233</abc>
    </testing2>
</myroot>

where all elements that were in the oldspace namespace are now in the newspace namespace.

Answer 2

Here's an option that allows you to pass the old and new namespace URIs in as xsl:param s.

XML Input (Borrowed from Matthew's answer; thanks!)

<os:myroot xmlns:os="com.help.me.2014">
    <?keep-this?>
    <os:testing abc='3' def='9'>
        <!-- This is a child -->
        <os:item>1234</os:item>
    </os:testing>
    <!-- this element is in the default namespace -->
    <testing2>
        <abc>112233</abc>
    </testing2>
</os:myroot>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="oldns" select="'com.help.me.2014'"/>
  <xsl:param name="newns" select="'com.help.me.2015'"/>

  <xsl:template match="@*|node()" name="ident">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*" priority="1">
    <xsl:choose>
      <xsl:when test="namespace-uri()=$oldns">
        <xsl:element name="{name()}" namespace="{$newns}">
          <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
      </xsl:when>
      <xsl:otherwise>
        <xsl:element name="{name()}" namespace="{namespace-uri()}">
          <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

XML Output

<os:myroot xmlns:os="com.help.me.2015"><?keep-this?>
   <os:testing abc="3" def="9"><!-- This is a child -->
      <os:item>1234</os:item>
   </os:testing><!-- this element is in the default namespace -->
   <testing2>
      <abc>112233</abc>
   </testing2>
</os:myroot>

Here's an XSLT 2.0 option that produces the same output...

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="oldns" select="'com.help.me.2014'"/>
  <xsl:param name="newns" select="'com.help.me.2015'"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*" priority="1">
    <xsl:element name="{name()}" namespace="{
      if (namespace-uri()=$oldns) then $newns else namespace-uri()}">
      <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

---

Here's another 2.0 example that handles multiple namespace uris. The old and new uris are passed in as a string with commas as delimiters.

The order of the uris are important. The first old uri corresponds to the first new uri. The second old uri corresponds to the second new uri. Etc.

XML Input (updated to have more than one namespace uri)

<os:myroot xmlns:os="com.help.me.2014">
    <?keep-this?>
    <os:testing abc='3' def='9'>
        <!-- This is a child -->
        <os:item>1234</os:item>
    </os:testing>
    <!-- this element is in the default namespace -->
    <testing2>
        <abc>112233</abc>
    </testing2>
    <os2:testing xmlns:os2="com.help.me.again.2014">
        <os2:item>ABCD</os2:item>
    </os2:testing>
</os:myroot>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="oldns" select="'com.help.me.2014,com.help.me.again.2014'"/>
  <xsl:param name="newns" select="'com.help.me.2015,com.help.me.again.2015'"/>

  <xsl:variable name="oldns-seq" select="tokenize($oldns,',')"/>
  <xsl:variable name="newns-seq" select="tokenize($newns,',')"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*" priority="1">
    <xsl:variable name="nsIdx" select="index-of($oldns-seq,namespace-uri())"/>
    <xsl:element name="{name()}" namespace="{
      if (namespace-uri()=$oldns-seq) then $newns-seq[$nsIdx] else namespace-uri()}">
      <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

XML Output

<os:myroot xmlns:os="com.help.me.2015"><?keep-this?>
   <os:testing abc="3" def="9"><!-- This is a child -->
      <os:item>1234</os:item>
   </os:testing>
   <!-- this element is in the default namespace -->
   <testing2>
      <abc>112233</abc>
   </testing2>
   <os2:testing xmlns:os2="com.help.me.again.2015">
      <os2:item>ABCD</os2:item>
   </os2:testing>
</os:myroot>