如何仅将可见单元格从工作簿复制到工作簿？

Question

I've never used VBA before, I don't know the commands and stuff. I really trying and I need some help please. I've to copy only the visible data from specified columns and paste to another worksheet, but I receive Subscript out of range error, while running the code. In the code I've to select the rows from the 7th row and I think I coded this a bit rough. Can anyone check my code why is this not working? Any suggestions for a better solution is appreciated.

Sub CopyData()

Windows("Source.xlsx").Activate
Range("D7, F7, G7, I7, J7, K7, L7, M7, O7, AD7, AX7, CO7, CQ7, CR7, AX7").Select
Range(Selection, Selection.End(xlDown)).Select

If Selection.EntireColumn.Hidden = False Then
Selection.Copy

End If

Windows("Destination.xlsx").Activate
Range("A2").Select
ActiveSheet.Paste

End Sub

Answer 1

Give this a shot:

Sub CopyData()

'set variables for wkb and ws to copy
Dim wbSource As Workbook
Set wbSource = Workbooks("Source.xlsx")

Dim wsCopy As Worksheet
Set wsCopy = wbSource.Worksheets("Sheet1") 'change name as needed

'set variables for wkb and ws to paste
Dim wbDest As Workbook
Set wbDest = Workbooks("Destination.xlsx")

Dim wsDest As Worksheet
Set wsDest = wbDest.Worksheets("Sheet1")

'copy visible cells for specific range
With wsCopy

    Dim lRow As Long
    lRow = .Range("D" & .Rows.Count).End(xlUp).Row

    Dim rCopy As Range
    Set rCopy = Union(.Range("D7:D" & lRow), .Range("F7:F" & lRow), _
        .Range("G7:G" & lRow), .Range("I7:I" & lRow), .Range("J7:J" & lRow), _
        .Range("K7:K" & lRow), .Range("L7:L" & lRow), .Range("M7:M" & lRow), _
        .Range("O7:O" & lRow), .Range("AD7:AD" & lRow), .Range("AX7:AX" & lRow), _
        .Range("CO7:CO" & lRow), .Range("CQ7:CQ" & lRow), .Range("CR7:CR" & lRow))

End With

'paste
rCopy.SpecialCells(xlCellTypeVisible).Copy wsDest.Range("A2")

End Sub

Answer 2

Dim rng As Range
Set rng = Application.Intersect(ActiveSheet.UsedRange, Range("A1:H500"))'range depends your work
Windows("Destination.xlsx").Activate
rng.SpecialCells(xlCellTypeVisible).Copy Destination:=Range("A2")

or you just use,

ActiveSheet.UsedRange.SpecialCells(xlCellTypeVisible)

without intersection method. Totally depends on your work.