如何在 Groovy 中转义特殊字符，不包括 unicode

Question

I would like to escape all the special characters in a string except for unicode characters (\\u), since I would still like to display non-English characters correctly. I am currently using the StringEscapeUtils.escapeJava() method, but have not found a way to exclude specific characters (\\u for unicode, in this instance). The only alternative I can think of is to call replace or replaceAll for each special character except \\u, which doesn't seem ideal. Is there a better way to do this?

Ex:

"Los 
niños"

should be converted to "Los\\nniños" instead of "Los\\nni\ños"

Answer 1

Ok, so if we look into the code of StringEscapeUtils , we can see the escapeJava method here :

public static final String escapeJava(final String input) {
    return ESCAPE_JAVA.translate(input);
}

Which uses ESCAPE_JAVA which is defined here

public static final CharSequenceTranslator ESCAPE_JAVA = 
      new LookupTranslator(
        new String[][] { 
          {"\"", "\\\""},
          {"\\", "\\\\"},
      }).with(
        new LookupTranslator(EntityArrays.JAVA_CTRL_CHARS_ESCAPE())
      ).with(
        JavaUnicodeEscaper.outsideOf(32, 0x7f) 
    );

So, I think it's this last bit which is giving you the undesired escaping...

So we can roll our own... Given your input string:

def input = '''Los 
niños'''

We can import the classes, and create our own LookupTranslator (ripping off the first bits from commons-lang):

import org.apache.commons.lang3.text.translate.EntityArrays
import org.apache.commons.lang3.text.translate.LookupTranslator

def translator = new LookupTranslator([["\"", "\\\""], ["\\", "\\\\"]] as String[][]).with(
    new LookupTranslator(EntityArrays.JAVA_CTRL_CHARS_ESCAPE())
)

And then, we can escape your input String, and check the result is as expected:

assert translator.translate(input) == 'Los \\nniños'

If you need the escaping for the unicode chars below 32 (but obviously, not the higher code chars), you can change your translator to:

import org.apache.commons.lang3.text.translate.EntityArrays
import org.apache.commons.lang3.text.translate.JavaUnicodeEscaper
import org.apache.commons.lang3.text.translate.LookupTranslator

def translator = new LookupTranslator([["\"", "\\\""], ["\\", "\\\\"]] as String[][]).with(
    new LookupTranslator(EntityArrays.JAVA_CTRL_CHARS_ESCAPE())
).with(JavaUnicodeEscaper.below(32))

All these are from commons-lang3 which I assume is the version you are using...