当我们传递用“（双反转逗号）引用的参数时，批处理脚本问题

Question

I have written below scripts which will ask user to input password as parameter if I enter password "Hello&123" it fails but it is working for other case like !Hello&123> please suggest some good approach to overcome this situation.

TestScript1.bat

@echo off
setlocal

set "psCommand=powershell -Command "$pword = read-host 'Enter password:' -AsSecureString ; ^
      $BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword); ^
            [System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR)""
for /f "usebackq delims=" %%p in (`%psCommand%`) do set password=%%p
if "%password%" == "" @echo password cannot be empty & goto DIE
TestScript2.bat.bat testuser "192.168.1.1" "%password%"
endlocal

:DIE
exit /b 1

TestScript2.bat

@echo off

echo n | psftp %1@%2 -pw %3 -b Test3.bat >> TestLog.log 2>&1

Answer 1

You need to use delayed expansion when you try to expand the variable.
Delayed expansion is always safe for any content.
But with delayed expansion there are problems with exclamation marks and carets.
That's why you should enabled it after the set "password=%%p" .

@echo off
setlocal DisableDelayedExpansion
set "psCommand=powershell -Command "$pword = read-host 'Enter password:' -AsSecureString ; ^
      $BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword); ^
            $str=[System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR); ^
            Write-host('#'+$str)""
for /f "usebackq delims=" %%p in (`%psCommand%`) do set "password=%%p"
setlocal EnableDelayedExpansion
set "password=!password:*#=!"
if not defined password (

    echo password cannot be empty
    goto :DIE
)
echo It works: pwd=!password!
TestScript2.bat testuser "192.168.1.1" "!password!"

But you will get the next problem with TestScript2.bat, as the expansion itself is safe, but you can't transfer an arbitrary password to a function or batch file by value (it's really impossible).

So you should transfer it by ref instead by value.

TestScript2.bat testuser "192.168.1.1" password

And use it in TestScript2.bat again with !%~3!

But to call the psftp command with the password causes again the problem with arbitrary values.
You need to escape the content to a safe format, in this case you have to regard the rules of psftp.
I tested, psftp replaces \\"" to " .

TestScript2.bat

@echo off
setlocal EnableDelayedExpansion
set "password=!%~3!"
set "password=!password:"=\""!"
... more replace rules
echo n | psftp %1@%2 -pw "!password!" -b Test3.bat >> TestLog.log 2>&1

Answer 2

I think what you want is something like this:

SET Test="Hello"
FOR /F "TOKENS=2 DELIMS==" %a in ('SET Test') DO @ECHO %~a

The %~a strips any quotes off.

Answer 3

The ampersand and the > would both need to be escaped ( !Hello^&123^> ) as they currently are not %3 is received as !Hello .

You can use delayed expansion to get around this:

setlocal enableDelayedExpansion
TestScript2.bat testuser "192.168.1.1" !password!