如何在Perl数组或标量中存储git命令的输出？

Question

In my code I have

git diff --numstat

I know I could create a file with

git diff --numstat > log.log

But is it even possible to pass this into an array or scalar of some sort? I was thinking something like this but I'm not sure why it doesn't compile.

my @array;
push (@array, git diff --numstat);

Answer 1

Use backticks, also known more generally as qx// :

• qx/STRING/
• `STRING`
  A string which is (possibly) interpolated and then executed as a system command with /bin/sh or its equivalent. Shell wildcards, pipes, and redirections will be honored. The collected standard output of the command is returned; standard error is unaffected. In scalar context, it comes back as a single (potentially multi-line) string, or undef if the command failed. In list context, returns a list of lines (however you've defined lines with $/ or $INPUT_RECORD_SEPARATOR ), or an empty list if the command failed.

You have options, and which is better depends on what you want to do with the output.

To read all of the standard output into a scalar, use the operator in scalar context as in

$output = `git diff --numstat`;

In list context with the default value of $/ , perl splits the output into separate lines. If you want to append the git output to the end of an existing array, use push , as in

push @array, `git diff --numstat`;

Although you mentioned push specifically in your question, I'm having a hard time imagining why you'd mix the output of git with something else. Storing the output in an array directly is simpler:

@array = `git diff --numstat`;

Note that the list of lines returned retain their end-of-line characters. To create a new array and remove all of the newlines in one line, write

chomp(@array = `git diff --numstat`);

or even

chomp(my @array = `git diff --numstat`);

if you're running under use strict .

Error Handling

For code that you plan to use more than once or twice, you should check that `git diff --numstat` , or any other command whose output you want to read, actually succeeded. Otherwise, with the warnings pragma enabled, you'll see lots of diagnostic messages about undefined variables or missing output.

In scalar context, failure will return the undefined value. Check it as in

my $output = `git diff --numstat`;
die "$0: git may not be installed" unless defined $output;

Failure in list context produces an empty list.

my @output = `git diff --numstat`;
die "$0: git may not be installed" unless @output;