Haskell将元组列表映射到元组列表

Question

I'm trying to map a list of tuples into a different list of tuples with no luck.

Example input:

a = [("eo","th"),("or","he")]

Example output:

[('e','t'),('o','h'),('o','h'),('r','e')]

I have tried:

map (\(a,b) -> (a!!0,b!!0):(a!!1,b!!1):[]) a

but it produces:

[[('e','t'),('o','h')],[('o','h'),('r','e')]]

Answer 1

You have to use concat on your result or use concatMap instead of map . After all, you return lists in your map and therefore get a list of lists.

---

Let's give your function a name and a type:

magic :: [([Char], [Char])] -> [(Char, Char)]

Now, we can think of this as a two-step process: from every pair in the original list we're going to get a list:

magicPair :: ([Char], [Char]) -> [(Char, Char)]
magicPair (a,b) = zip a b

Now we need to map magicPair over all elements in your original list and concatenate the result:

magic xs = concat (map magicPair xs)

The combination concat . map f concat . map f is so common that there is a function called concatMap for this:

magic xs = concatMap magicPair xs

And using a function f on a pair instead of two arguments is also common, so magicPair = uncurry zip :

magic xs = concatMap (uncurry zip) xs

We can now remove xs on both sides to end up with the final variant of magic :

magic = concatMap (uncurry zip)

Answer 2

这是给您输出的快速方法

simplify = (>>= uncurry zip)