如何使一个数组中的值与另一个数组（VBA）中的值相同？

Question

I want to create a piece of code that lets me assign a value from a array to another array, which are of different lengths. This is what I have so far.

A(1) = 0
A(2) = 0
A(3) = 6
A(4) = 5
A(5) = 7

n = 0

For i = 1 To 5
If A(i) <> 0 Then
    n = n + 1
End If
Next i

ReDim B(1 To n) As Integer
For j = 1 To n
    For i = 1 To 5
        If A(i) <> 0 Then
            B(j) = A(i)
        End If
    Next i
Next j

MsgBox B(2)

At the moment this returns 7 whereas it should return 5, all values in B are 7. How can I get this code to run?

Answer 1

The fact that you have nested loops should alarm you: this would be executed n * 5 times, which cannot be correct.

Change the second part so it only uses one loop, like this:

ReDim B(1 To n) As Integer
j = 1
For i = 1 To UBound(A)
    If A(i) <> 0 Then
        B(j) = A(i)
        j = j + 1
    End If
Next i

Note also that using UBound instead of 5 makes your code more generic. Note also that this loop is very similar to the loop that calculates n . The only difference is that you assign to B(j) .

You could in fact combine it with the first loop, if you would re-dimension B twice, the second time with Preserve :

ReDim B(1 To UBound(A)) As Integer
n = 0
For i = 1 To UBound(A)
    If A(i) <> 0 Then
        n = n + 1
        B(n) = A(i)
    End If
Next i
' Shorten the array without losing data:
ReDim Preserve B(1 To n)

Answer 2

You are going to have to check B for the first empty array element and exit the loop so you do not continue to write.

Dim A() As Variant, B() As Variant
Dim i As Long, j As Long, n As Long

A = Array(0, 0, 6, 5, 7)  '<~~ 0 to 4, not 1 to 5

n = 0
For i = LBound(A) To UBound(A)
    If A(i) <> 0 Then
        n = n + 1
    End If
Next i

ReDim B(1 To n) '<~~ 1 to 3

For i = LBound(A) To UBound(A)
    If A(i) <> 0 Then
        For j = LBound(B) To UBound(B)
            If IsEmpty(B(j)) Then
                B(j) = A(i) '<~~ assigned a value; exit loop
                Exit For
            End If
        Next j
    End If
Next i

For j = LBound(B) To UBound(B)
    Debug.Print B(j)
Next j

Given that arrays can be either zero-based or one-based, I prefer to use the LBound and UBound functions to define their scope.