Excel VBA：创建新工作表的超链接

Question

Wondering if this is even possible, but:

So I got a macro button that inserts values into the sheet from a UserForm, and here's a visual example how it approximately looks like:

 <table style="width:100%"> <tr> <td>OrderID:</td> <td>Product</td> <td>Q</td> <td>Invoice</td> </tr> <tr> <td>1</td> <td>Potato</td> <td>1337</td> <td><a href="url">Open Invoice</a></td> </tr> </table> 

The "Open Invoice" link I create with this code:

    Sheets("Sales").Hyperlinks.Add Sheets("Sales").Cells(emptyRow, 9), "", Sheets("Sales").Name, "", "Open Invoice"

I would like that, whenever I click "Open Invoice", it would create a new Sheet (preferably a new Excel window) and then the data transfers into a template (the transferring and template I think I will manage myself)

Thanks!

Answer 1

Do this to set your hyperlink:

Dim hlRange as Range
Set hlRange = Sheets("Sales").Cells(emptyRow, 9)
With hlRange.Hyperlinks
    .Delete
    .Add Anchor:=hlRange, _
         Address:="", _
         SubAddress:=hlRange.Address, _
         TextToDisplay:="Open Invoice"
End With

This creates a hyperlink that links back to itself, so it's a valid reference but it doesn't go anywhere else .

Then, using the Worksheet_FollowHyperlink event procedure to create a new Workbook from your template, and from there you can insert the data as needed:

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
Dim wb as Workbook
Dim ws as Worksheet
' If there are other hyperlinks in this sheet which should NOT trigger the new file, then you will need to add an Intersect test and exit sub early.

'Add a new workbook
Set wb = Workbooks.Open("path to template file")  '## Modify as needed
Set ws = wb.Worksheets(1)                         '## Modify as needed

'Add the data to the new sheet in new workbook
'  -- code here, or call another procedure to do the operation --

End Sub