如何删除与我提供的文本匹配的前 2 行（使用 sed ）？

Question

#file.txt contains following lines :
abc
def
def
abc
abc
def

Answer 1

Using "sed"

While @EdMorton has pointed out that sed is not the best tool for this job (if you wonder why exactly, see my answer below and compare it to the awk code), my research showed that the solution to the generalized problem

Delete occurences "N" through "M" of a line matching a given pattern using sed

indeed is a very tricky one in my opinion. There seem to be many suggestions for how to replace the "N"th occurence of a matching pattern with sed , but I found that deleting a specific matching line (or a range of lines) is a much more complex undertaking.

While the generalized problem with arbitrary values for N, M, and the pattern would probably be solved best by writing a "sed script generator" on the basis of a Finite State Machine, the solution to the special case asked by the OP is still simple enough to be coded by hand. I must admit that I wasn't very familiar with the obfuscated intricacies of the sed command syntax before, but I found this challenge to be quite useful for gaining more experience with non-trivial sed usage.

Anyway, here's my solution for deleting the first two occurences of a line containing "abc" in a file. If there's a simpler approach, I'm eager to learn about it, as this has taken me some time now.

A final caveat: this assumes GNU sed , as I was unable to find a solution with POSIX sed :

sed -n ':1;/abc/{n;b2;};p;$b4;n;b1;:2;/abc/{n;b3;};p;$b4;n;b2;:3;p;$b4;n;b3;:4;q' file

or, in more verbose syntax:

sed -n '
    # BEGIN - look for first match
        :first;
        /abc/ {
            # First match found. Skip line and jump to second section
            n; bsecond;
        };
        # Line does not match. Print it and quit if end-of-file reached
        p; $bend;
        # Advance to next line and start over
        n; bfirst;
    # END - look for first match

    # BEGIN - look for second match
        :second;
        /abc/ {
            # Second match found. Skip line and jump to final section
            n; bfinal;
        }
        # Line does not match. Print it and quit if end-of-file reached
        p; $bend;
        # Advance to next line and start over
        n; bsecond;
    # END - look for second match

    # BEGIN - both matches found; print remaining lines
        :final;
        # Print line and quit if end-of-file reached
        p; $bend;
        # Advance to next line and start over
        n; bfinal;
    # END - print remaining lines

    # QUIT
    :end;
    q;
' file

Answer 2

sed is for simple substitutions on individual lines, that is all. For anything else you should be using awk:

$ awk '!(/abc/ && ++c<3)' file
def
def
abc
def