如何使Perl打印字符串的前十行？

Question

I'm trying to show the first ten lines of a large string (first 10 lines of a paragraph). I've tried to use:

 $lines = head-10 $string

I saw some examples that use while loops but my script can't facilicate that, I need it to be a variable.

Next I tried to use:

 $string = perl -pe'$.>10&&last'

which gave me the desired result by typing

String= "$(string | head -n10)"

Answer 1

Perl allows you to open a filehandle on a string. You can then use filehandle idioms to "read" the string.

my $string = <<"HERE";
This is the first line
This is the second line
3rd
4th
5th
6th
seventh
one plus seventh
eighth
tenth minus one
tenth
should not go this far
way to far
okay stop now, srsly
This is the last line
HERE


open my $fh, '<:utf8', \ $string or die;
while( 0 .. 10 ) {
    print { STDOUT } scalar <$fh>;
    }
close $fh;

In this example, instead of a filename I give open a reference to a scalar. Now I have a filehandle on that scalar.

In the while , I use the flip-flop operator. It looks like the range operator, but in boolean context it's different. It is true when the first condition is true, and stays true until the second condition is true. That is, it turns on, stays on, then turns off.

When you use number literals with the flip flop, it looks at the line number for the currently read filehandle (in this case $fh). So, we turn it on when the line number is 0 and turn it off when the line number is 10. That means that the loop doesn't execute when the line number is 10 because the condition is now false. But, that's okay because that's actually line 11.

Or, you can do that with a counting for loop:

open my $fh, '<:utf8', \ $string or die;
for( my $i = 0; $i <= 10; $i++ ) {
    print { STDOUT } scalar <$fh>;
    }
close $fh;

In both examples I use scalar <$fh> to get the next line because I used it inline with the print , a list context operator. I don't want all the lines. I surround the output handle in braces to set it apart from the rest of what's going on.

But, you're asking about it being in a bash script it looks like. Anything you can do in a "normal" perl program you can do in the argument to -e :

perl -e 'open my $fh, q(<:utf8), \ $ARGV[0] or die;
    for( my $i = 0; $i <= 10; $i++ ) {
        print { STDOUT } scalar <$fh>;
        }
    close $fh;' string_arg

Answer 2

Try the following solution between >>>> START... and <<<< END... comments (The remainder is wrapper code to turn it into a standalone script for demo/testing purposes). After the solution section, $s_start will contain the first 10 lines of $s_raw :

#!/usr/bin/perl
#
use warnings;

my (
      $n_lines
    , $s_raw
    , $s_start
    , $s_thisline
);

{ local $/ = undef; $s_raw = <DATA>; }

#>>>> START of core code section
$n_lines = 0;
open $fh_raw, "<", \$s_raw;
while ( ($n_lines < 10) && ($s_thisline = <$fh_raw>) ) {
    $s_start .= $s_thisline;
    $n_lines++;
}
close $fh_raw;
#<<<< END of core code section

print $s_start;
exit(0);

__DATA__
This is a test
with lots of lines
and
a bit
repetitive in nature
however
it 
serves the purpose
of demonstrating
the
code above
...(arbitrarily more stuff) ...

Answer 3

If you want to do this in the code, split the paragraph into a list, use an array slice to get the first 10 elements and join them back together again by adding the newlines back.

#!/usr/bin/perl

use strict;
use warnings;


my $string = "line1
line2
line3
line4
line5
line6
line7
line8
line9
line10
line11
line12";

#  turn the lines into a list by splitting on newline
my @lines = split "\n", $string;

#  take an array slice of the first 10 list items and join them into a string
#  delimited by a newline
my $first_ten = join "\n", @lines[0 .. 9];

#  print your 10 lines
print $first_ten;