类型类声明类型不匹配

Question

I am trying to make my Cell type a member of the Show typeclass. The show a line is problematic. How do I make sure that the a is a Char in that show case? I was hoping the ordering of the statements would just let fallthrough handle it, but that doesn't do it.

data Cell = Solid | Blank | Char

instance Show (Cell) where
    show Solid = "X"
    show Blank  = "_";
    show a = [a]

main = print $ show Solid

Answer 1

You can't make sure that a is a value of type Char because that simply can't be the case. a will always be a value of type Cell , specifically it will be the value Char (which has no relation to the type Char ).

What you seem to want is to have Cell 's third constructor contain a value of type Char . To do that your constructor needs a parameter:

data Cell = Solid | Blank | CharCell Char

instance Show (Cell) where
    show Solid = "X"
    show Blank  = "_"
    show (CharCell a) = [a]

The CharCell a case matches if the constructor CharCell has been used and a will be the value used as CharCell 's parameter (and thus have type Char as that is CharCell 's parameter type).

Answer 2

data Cell = Solid | Blank | Char

This is a tagged union , which means Solid , Blank , and Char are constructor names, not types. For example, Char :: Cell .

I suspect what you meant was something such as this:

data CellType = CellConstructor Char

instance Show CellType where
  show (CellConstructor c) = [c]

Examples:

• CellConstructor 'X' :: CellType
• CellConstructor '_' :: CellType
• CellConstructor 'a' :: CellType

It is customary to give the type and constructor the same name if there is only one constructor.

data Cell = Cell Char

If there is only one constructor with only one field then it is customary to use a newtype.

newtype Cell = Cell Char 

Answer 3

Char here is not the type Char ; it is a new data constructor named Char . If you want Cell to be Solid , Blank , or a value of type Char , you need

data Cell = Solid | Blank | Char Char

instance Show Cel where
    show Solid = "X"
    show Blank = "_"
    show (Char c) = [c]

Some examples:

> show Solid
"X"
> show Blank
"_"
> show (Char '4')
"4"

Answer 4

Look at the definition of the typeclass Show , mainly at the show function:

class Show a where
    show      :: a   -> String

Now, does your instance for your Cell type satisfy it? The first case, show Solid = "X" does - Solid is Cell and "X" is a String. The same goes for the second case. But what is the third case? You defined it as show a = [a] so the type signature is Cell -> [Cell] and [Cell] is not a String . Therefore you get a type mismatch.