Excel 或 VBA - 从另一个工作表中的动态列填充下拉列表，没有重复项

Question

I don't know if this is even possible, but I am trying to do a couple of things that require me to populate drop down lists, and a normal cell by cell list, based on the items in a column on another sheet. I know how to do this with a regular column, but the column I want to use changes length and has many duplicate values in it, as it is an inventory of sorts.

So on this sheet, in C5,

that value should be able to be selected from a drop down list based on the contents of column B in the second sheet, but also without having to scroll through duplicates.

I am happy to use either VBA or general excel formulas to achieve this. I am also aware that I don't think I have explained this very well so please feel free to prompt me for more information as required.

Answer 1

Here is a start. I assume the the list of items is in Sheet2 somewhere from B1 through B1000 . It's OK if the range is only partially filled (adjust the 1000 to suit your needs) .

The code scans this list and builds a DV string. The Data Validation is then applied to Sheet1 cell C5 :

Sub setupDV()
    Dim rSource As Range, rDV As Range, r  As Range, csString As String
    Dim c As Collection

    Set rSource = Sheets("Sheet2").Range("B1:B1000")
    Set rDV = Sheets("Sheet1").Range("C5")
    Set c = New Collection
    csString = ""
    On Error Resume Next
    For Each r In rSource
        v = r.Value
        If v <> "" Then
            c.Add v, CStr(v)
            If Err.Number = 0 Then
                If csString = "" Then
                    csString = v
                Else
                    csString = csString & "," & v
                End If
            Else
                Err.Number = 0
            End If
        End If
    Next r
    On Error GoTo 0

    'MsgBox csString

    With rDV.Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:=csString
        .IgnoreBlank = True
        .InCellDropdown = True
        .InputTitle = ""
        .ErrorTitle = ""
        .InputMessage = ""
        .ErrorMessage = ""
        .ShowInput = True
        .ShowError = False
    End With
End Sub