Excel公式可识别列中的最新非空白单元格

Question

I have an extract from an electronic health record for an appointment schedule, that although it is readable in Excel, the data is not sortable or interpretable in an easy manner. I have successfully gathered much of the data into one field which is separated by commas (which will I will then use text to columns to separate). I now have the info in two separate columns. Column A - provider name and date of service Column B - all other necessary info

The problem - column a and column b do not match. For example A2 has the provider name and date of service, but the corresponding additional details come on b8. There is also not always a one to one match (there are fewer entries in column A than B.

What I want - I need to link (in the above example) A2 to B8 and so forth throughout the columns. In the case where there are multiple entries in column b for each in a, I would always want the most recent non blank value in column b to match to B

I have tried index, lookup, match and nothing are working properly. Any assistance in pointing me in the right direction would be helpful.

Answer 1

Assuming that the data in Columns A and B come in the same order (meaning that the Nth entry in Column A is the Nth entry in Column B, spaces notwithstanding), and that cells B2 to B7 are blank, it just sounds to me like you need to delete blank cells.

IMPORTANT: before doing anything, make sure you are working from a copy of your data. I don't want to be responsible for you losing anything permanently...

Try selecting your entire dataset (everything in Columns A & B) and going to Find&Select>Goto Special (Alt+H,FD,S) in Excel 2016. Probably something similar in earlier versions.

In that screen there is an option to select blanks. Do that, then back on your worksheet simply delete the selected cells (ctrl + -) and tell Excel to shift the remaining cells UP. Your corresponding data in columns A & B should now be aligned on the same rows, right?

Answer 2

Based on your description and assuming you data is layed out as:

    (A)      |    (B)
(1)          |
(2) AAA 111  |
(3)          |
(6)          |  Something
(7) BBB 222  |
(8)          |
(11)         |  Something more
(12) CCC 333 |
(13)         |
(16)         |  Something Else

Please note jumps in row numbers

In C2 use the following:

=OFFSET($A$2,(ROW(A2)-2)*5,0,1,1)

and in D2 use the following

=OFFSET($A$2,(ROW(A2)-2)*5+4,1,1,1)

now to deal with 0 showing up when the entry is blank you could wrap the offset function in an if statement

=if(OFFSET($A$2,(ROW(A2)-2)*5+4,1,1,1)=0,"",OFFSET($A$2,(ROW(A2)-2)*5+4,1,1,1))

Answer 3

Assuming there is at least 1 entry in column A which belongs to column B you can use this to have a non-volatile function:

D1: {=IFERROR(INDEX(A:A,MATCH(SMALL(IF(B$1:INDEX(B:B,MATCH("zzz",B:B))<>"",ROW(B$1:INDEX(B:B,MATCH("zzz",B:B)))),ROW()),IF(A$1:INDEX(A:A,MATCH("zzz",A:A))<>"",ROW(A$1:INDEX(A:A,MATCH("zzz",A:A)))),1)),"")}
E1: {=IFERROR(INDEX(B:B,SMALL(IF(B$1:INDEX(B:B,MATCH("zzz",B:B))<>"",ROW(B$1:INDEX(B:B,MATCH("zzz",B:B)))),ROW())),"")}

And to not get the entry of column a multiple times, just use for D2:

D2: {=IFERROR(IF(INDEX(A:A,MATCH(SMALL(IF(B$1:INDEX(B:B,MATCH("zzz",B:B))<>"",ROW(B$1:INDEX(B:B,MATCH("zzz",B:B)))),ROW()),IF(A$1:INDEX(A:A,MATCH("zzz",A:A))<>"",ROW(A$1:INDEX(A:A,MATCH("zzz",A:A)))),1))=INDEX(A:A,MATCH(SMALL(IF(B$1:INDEX(B:B,MATCH("zzz",B:B))<>"",ROW(B$1:INDEX(B:B,MATCH("zzz",B:B)))),ROW()-1),IF(A$1:INDEX(A:A,MATCH("zzz",A:A))<>"",ROW(A$1:INDEX(A:A,MATCH("zzz",A:A)))),1)),"",INDEX(A:A,MATCH(SMALL(IF(B$1:INDEX(B:B,MATCH("zzz",B:B))<>"",ROW(B$1:INDEX(B:B,MATCH("zzz",B:B)))),ROW()),IF(A$1:INDEX(A:A,MATCH("zzz",A:A))<>"",ROW(A$1:INDEX(A:A,MATCH("zzz",A:A)))),1))),"")}

But as said: If a value in column A does not have any value in column B, then it will be skipped!

This are all array formulas and will be entered without the {} but must to be confirmed with Strl + Shift + Enter !