如何修改gdb中的断点行？

Question

I set a breakpoint and set its conditions and some other commands. Now I realize that I should had set it a few lines ahead. How can I change the line of the breakpoint without deleting it and losing its settings?

Answer 1

How can I change the line of the breakpoint without deleting it and losing its settings?

You can't.

What you can do is use save breakpoints /tmp/bp.txt command to save current settings for all breakpoints, edit the /tmp/bp.txt file to update the line info (or anything else), and finally delete to remove current breakpoints and source /tmp/bp.txt to reload them.

Answer 2

Considering that you will probably want to do that on many occasions, I suggest adding the following to your .gdbinit :

define loadbp
  delete breakpoints
  source .gdbbp
end
document loadbp
  Set stored breakpoints after deleting any current breakpoints.

The breakpoints to load (set) are expected in ./.gdbbp which is the file created by savebp, but can
be edited manually.

Some breakpoints may not be set because the needed shared object hasn't been loaded yet.  gdb
doesn't prompt when such breakpoint commands are not set interactively.  Consequently, it may be
necessary to run this command again, once the shared object has been loaded.  To account for cases
in which shared objects are loaded automatically by the dynamic loader, this command also sets a
breakpoint in main.  This ensures that there is an early opportunity to call this command again to
set shared object breakpoints.
end

define savebp
  save breakpoints .gdbbp
end
document savebp
  Store current breakpoints in .gdbbp for retrieval using loadbp.
end

To use those commands, you need to source .gdbinit or restart gdb . Then, type savebp and hit Enter at the gdb command prompt, edit ./.gdbbp as desired, then type loadbp and hit Enter at the gdb command prompt.

Note that, as written, those commands save and load .gdbbp relative to the current directory. Usually, that's the directory from which you started gdb , but you can change it from within gdb , so pay attention to where the file is save. (You can run the pwd command at the gdb command prompt to see what the current directory is.)