从Excel VBA中的一系列单元格中获取列x的单元格

Question

I have a Range of Cells, let's say: Range("A1:D20") which is stored in a Range variable. In my case, the range is actually a named range. Eg

Set rngList = Range("LIST")

I'm trying to use a 'for each' loop to traverse only the Cells in column 2. EDIT: this is a relative reference, not absolute: 2nd column of the range.

Eg

for each rngCell in rngList.Columns(2)
   //Do stuff
next

The .Columns(2) doesn't work. Is there a simple way to do this?

Cheers

Answer 1

Add .Cells after .Columns(2) :

For Each rngCell In Range("LIST").Columns(2).Cells
   Debug.Print rngCell
Next

Answer 2

You could create another range directly from your existing range using column B (efficient), or you could just check if each cell in your existing range is in column 2, before doing your stuff:

Method 1 (create a derivative range):

Sub method1()

    Dim rngList As Range
    Dim rngList2 As Range

    Set rngList = Range("LIST")

    Set rngList2 = Range("B" & rngList.Row, Range("B" & (rngList.Row + rngList.Rows.Count - 1)))

    For Each rngCell In rngList2
        rngCell.Value = "hey1"
    Next rngCell

End Sub

Method 2 (check if cell is in column 2):

Sub method2()

    Dim rngList As Range

    Set rngList = Range("LIST")

    For Each rngCell In rngList
        If rngCell.Column = 2 Then
            rngCell.Value = "hey2"
        End If
    Next rngCell

End Sub

Answer 3

try this

For Each rngCell In Intersect(rngList, rngList.Parent.Columns(2))
'   //Do stuff
Next