对象'_Global'的方法'Range'在第二次运行时失败

Question

I am having a problem with the error:

Method 'Range' of Object'_Global' Failed

... on a section of code when it runs for the second time.

The entire program is to export information from an SQL database via access queries and create the source table that is then exported to an excel spreadsheet, the source table contains information from 14 different locations. The excel spreadsheet is therefore created 14 times (and is eventually emailed to 14 different people)

For the purpose of testing the code I have put it in a Do While loop to simulate the code having to run more than once, I have not done any programming in a few decades so I am very rusty, the section of code that is failing is:

.Cells.EntireRow.EntireColumn.Sort key1:=Range("G2"), order1:=xlDescending, Header:=xlYes

Full code:

Private Function Open_Excel_Spreadsheet()

    Dim Cnt As Integer 'Counter
    Cnt = 1

    Do While Cnt < 4

        Dim oExcel      As Excel.Application
        Dim oBook       As Excel.Workbook
        Dim oSheet      As Excel.Worksheet
        Dim LastRow     As Long
        Dim FirstNewRow As Long
        Dim i As Integer 'Row counter in the range of 2 to FirstNewRow
        i = 2

        Set oExcel = CreateObject("Excel.Application")
        Set oBook = oExcel.Workbooks.Open([MyDocsPath], , ReadOnly:=False)
        Set oSheet = oBook.Worksheets(1)

        oExcel.Visible = True

        'Find the last used row in Column A and set LastRow and FirstNewRow variables
        With oSheet
            LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        End With
        FirstNewRow = LastRow + 1

        Debug.Print Cnt; FirstNewRow

        'Format the Spreadsheet
        With oSheet
            .Sort.SortFields.Clear

            ' Next line generates "Method 'Range' of Object'_Global' Failed" the second time it runs
            .Cells.EntireRow.EntireColumn.Sort key1:=Range("G2"), order1:=xlDescending, Header:=xlYes

            .Cells(FirstNewRow, 5) = "=sum(E2:E" & [LastRow] & ")"
            .Cells(FirstNewRow, 6) = "=sum(F2:F" & [LastRow] & ")"
            For i = 2 To FirstNewRow
                .Cells(i, 7) = "=IF(+E" & [i] & "=0,0,Round(((+E" & [i] & "-F" & [i] & ")/E" & [i] & ")*100,2))"
            Next i
            .Range("E1:G1").EntireColumn.NumberFormat = "#,##0.00_);[Red]-#,##0.00"
            .Range("a1").EntireRow.EntireColumn.AutoFit
        End With

        'Save Workbook and drop Excel
        oBook.Close True

    Cnt = Cnt + 1
    Loop

End Function

Answer 1

As it sits, Range("G2") may or may not be referring to the G2 cell on the oSheet worksheet. The only thing that is certain is that it refers to the G2 cell on the worksheet that currently holds the ActiveSheet property .

Try it as,

.Cells.EntireRow.EntireColumn.Sort key1:=.Range("G2"), order1:=xlDescending, Header:=xlYes

Note .Range("G2") and not Range("G2") . This explicitly references the G2 on the worksheet referenced with the With... End With statement .