在VBA中，删除除这些特定的列以外的所有列

Question

I have numbers that correspond to columns in Excel: Columns 4, 5, 6, 7, 26, 28. These columns are dynamically changing depending on the worksheet and depend on the above code.

How can I delete all the columns in the worksheet EXCEPT for these columns?

Answer 1

Give this a try:

Sub KolumnKiller()
    Dim s As String, i As Long
    s = ",4,5,6,7,26,28,"
    Application.ScreenUpdating = False
        For i = Columns.Count To 1 Step -1
            If InStr(1, s, "," & i & ",") = 0 Then Cells(1, i).EntireColumn.Delete
        Next i
    Application.ScreenUpdating = True
End Sub

Note:

You can speed this up a bit by starting with something like 1000 rather than Columns.Count if you know that the far right-hand columns are already empty.

Answer 2

Updated for a silly mistake in my explanation!

I prefer not to respond to posts with no sample code in the question (effort in/effort out principle), but in this case there's a really important aspect that you'll need to consider: You have the choice of looping through each worksheet column and checking if it's in your target list or of just looping through your target list (obviously much quicker). The decision rides on one important question: is your columns list sorted?

I know your question shows the columns in order but I wanted to mention it in case there's any chance of the list becoming disordered or if other readers have unsorted columns.

The answer given by Gary's Student will work well and his code deals nicely with an out of sequence list (he's an experienced contributor to this site and the Instr solution keeps things nice and concise).

However, if you could ensure the list was in order (smallest to largest), or you were prepared to sort the list yourself, then you could have a much quicker solution, as it enables you only to loop through the target list. It's also a matter of preference but I like to manage row and column deletions in one batch, purely from a time perspective. So the code below is a sample of how you might do it:

    Dim ws As Worksheet
    Dim goers As Range
    Dim keepers As Variant
    Dim v As Variant
    Dim thisCol As Long
    Dim lastCol As Long

    'Your list of columns to keep
    keepers = Array(2, 4, 5, 8, 11, 12, 15)


    Set ws = ThisWorkbook.Worksheets("Sheet1")

    'Initialise goer at column 1 or set to nothing if 1 is a keeper
    Set goers = IIf(keepers(0) = 1, Nothing, ws.Columns(1))

    'Loop through the list extending the column range to next keep column
    lastCol = 1
    For Each v In keepers
        thisCol = v
        If thisCol - lastCol > 1 Then
            Set goers = DelCols(ws, goers, lastCol, thisCol)
        End If
        lastCol = thisCol
    Next

    'Extend to end of worksheet
    Set goers = DelCols(ws, goers, lastCol, ws.Columns.Count)

    'Delete the goers
    goers.Delete


End Sub
Private Function DelCols(ws As Worksheet, cols As Range, col1 As Long, col2 As Long) As Range
    'Helper function to deal with Union
    Dim rng As Range

    'Resize the columns from last+1 to this
    Set rng = ws.Columns(col1 + 1).Resize(, col2 - col1)
    If cols Is Nothing Then
        Set cols = rng
    Else
        Set cols = Union(cols, rng)
    End If

    Set DelCols = cols
End Function