Excel公式返回符合条件的范围，然后COUNTIF结果

Question

I've been struggling with this all day. I had the following sheet that worked fine. The user enters SUBJECT STATE, in this case KY for Kentucky. Below there is a table called, "FullCompDataSet", with 3 columns. I need to do 2 things from this data ( output shown below highlighted in yellow ):

A. Count the number of records in FullCompDataSet whose "ST/Prov" match the SUBJECT STATE. I had this formula:

=COUNTIF(FullCompDataSet[ST/Prov],SubjectStateAbbreviation)

B. Return the Key for each record. I had this formula:

{=SMALL(IF(FullCompDataSet[ST/Prov]=SubjectStateAbbreviation,FullCompDataSet[Key]),ROW()-18)}

All of that worked fine, but now instead of simply matching the Subject State to the St/Prov, I have a list of compatible states I need to match ( example list at bottom highlighted in teal ). So, the new output I need is:

A. 6 (because the subject state KY matches records in states of KY, IN, and TN)

B. 413, 420, 434, 418, 404, 410

Can anyone suggest the new formulas I'd need to use for A and B?? I've tried all sorts of combinations of VLOOKUP/INDEX/MATCH, OFFSET, INDIRECT but haven't been able to get it. My apologies if there was a better way to post this issue, I'm still learning to post. THANK YOU!

FullCompDataSet Table

Many-To-Many State Compatibility Map

Answer 1

Outside of using VBA I would use the following method; it's essentially a different in-sheet algo and or set of functions to the ones you're using. It will cater for changing dimensions of requested matches and as you see it also has adjustable output set. You'll essentially need to carry out 7 distinct function sets (easier than it sounds). I've included them in the picture; each color set uses the same function as shown in the comment. The algo works very well and uses nothing more complicated than a vlookup. I've used it on much larger and more complex datasets. You can also adapt it to function like a traditional Dictionary by assigning multiple key/identity sets.

Answer 2

If you have the latest version of office 365 you can use the following two formula to get what you want:

For the count:

=SUM(IF(ISNUMBER(SEARCH(FullCompDataSet[ST/Prov],TEXTJOIN(" ",TRUE,IF(CompatState[State]=SubjectStateAbbreviation,CompatState[Compatible States],"")))),1,0))

For the SMALL:

=SMALL(IF(ISNUMBER(SEARCH(FullCompDataSet[ST/Prov],TEXTJOIN(" ",TRUE,IF(CompatState[State]=SubjectStateAbbreviation,CompatState[Compatible States],"")))),FullCompDataSet[Key]),ROW(1:1))

Both are array formulas and must be confirmed with Ctrl-Shift-Enter on exiting edit mode. If done correctly Excel will put {} around the formulas.

The TEXTJOIN formula was introduced in OFFICE 365 in February 2016. It makes a single string of the states that are compatible. It is this string that the SEARCH tries to find a match. When it finds a match it is passed to the outside formulas. One to count and one to find the correct Key.