Perl取消引用子例程

Question

I have come across code with the following syntax:

$a -> mysub($b);

And after looking into it I am still struggling to figure out what it means. Any help would be greatly appreciated, thanks!

Answer 1

What you have encountered is object oriented perl.

it's documented in perlobj . The principle is fairly simple though - an object is a sort of super-hash, which as well as data, also includes built in code.

The advantage of this, is that your data structure 'knows what to do' with it's contents. At a basic level, that's just validate data - so you can make a hash that rejects "incorrect" input.

But it allows you to do considerably more complicated things. The real point of it is encapsulation, such that I can write a module, and you can make use of it without really having to care what's going on inside it - only the mechanisms for driving it.

So a really basic example might look like this:

#!/usr/bin/env perl
use strict;
use warnings;

package MyObject;

#define new object
sub new {
   my ($class) = @_;
   my $self = {};
   $self->{count} = 0;
   bless( $self, $class );
   return $self;
}
#method within the object
sub mysub {
   my ( $self, $new_count ) = @_;
   $self->{count} += $new_count;
   print "Internal counter: ", $self->{count}, "\n";
}

package main;
#create a new instance of `MyObject`. 
my $obj = MyObject->new();
#call the method, 
$obj->mysub(10);
$obj->mysub(10);

We define "class" which is a description of how the object 'works'. In this, class, we set up a subroutine called mysub - but because it's a class, we refer to it as a "method" - that is, a subroutine that is specifically tied to an object.

We create a new instance of the object (basically the same as my %newhash ) and then call the methods within it. If you create multiple objects, they each hold their own internal state, just the same as it would if you created separate hashes.

Also: Don't use $a and $b as variable names. It's dirty. Both because single var names are wrong, but also because these two in particular are used for sort .

Answer 2

That's a method call. $a is the invocant (a class name or an object), mysub is the method name, and $b is an argument. You should proceed to read perlootut which explains all of this.