SAS：总结proc sql

Question

I am working on a SAS project where I am being asked to sum down on rows. Here's the code I have:

proc sql;
  create table total as
    select 
      sum(ans1) as sum1,
      sum(ans2) as sum2,
      sum(ans3) as sum3,
      sum(ans4) as sum4
    from proj.scores;
quit;

My problem is there are 150 variables (labeled ans1-ans150). Is there a way to sum each of them without having to continue what I have all the way to 150?

Answer 1

I think the proper tool would make the whole process much easier. SQL does not have features for working with large lists of variables.

proc summary;
   output out=sum sum(ans1-ans150)=sum1-sum150;
   run;

Answer 2

Yes, you can do this using macro logic and replacing your 1, 2, 3... rows with a loop. This method uses a "backstop" variable so that the comma in your loop does not cause an error on the 150th iteration of the loop (this variable is dropped).

%macro summer;

    proc sql;
        create table total (drop = backstop) as select
            %do i = 1 %to 150;
                sum(ans&i.) as sum&i.,
            %end;
            "" as backstop
            from proj.scores;
    quit;

%mend summer;

%summer;

Answer 3

A better approach (in my opinion), is to use the macro this way:

data have;
input x1-x10;
datalines;
1 2 3 4 5 6 7 8 9 10
1 2 3 4 5 6 7 8 9 10
1 2 3 4 5 6 7 8 9 10
;;;;
run;

%macro sum_loop(prefix=, outfix=, start=1, end=);
%local i;
%do i = &start. %to &end.;  /* loop over start to end */
  sum(&prefix.&i.) as &outfix.&i.   /* the actual SQL statement */
  %if &i < &end %then %do; , %end;  /* that way you get commas after all non-last entries */
%end;
%mend sum_loop;

proc sql;
  create table total as
    select 
      %sum_loop(prefix=x,outfix=sum,start=1,end=10)
    from have
  ;
quit;

That way, the macro is just responsible for what you need looped. That makes it more reusable and easier to maintain - WHERE and FROM and such are separate.. Even better would be to split out the inner portion as its own macro, and have a generic looper macro, but here that might be overkill...