gradle没有激活任务来复制文件

Question

I am using following code in build.gradle that copies different configuration files for airship. However what I am finding is my tasks copyReleaseConfigFileTask / copyDebugConfigFileTask are not being called. Can anyone give hints as to why the tasks I have defined below are not getting executed?

task copyReleaseConfigFileTask(type: Copy) << {
    println "-> using airship release config"
    from 'app/src/main/assets/airshipconfig.properties.release'
    into 'app/src/main/assets/airshipconfig.properties'
}

task copyDebugConfigFileTask(type: Copy) << {
    println "-> using airship debug config"
    from 'app/src/main/assets/airshipconfig.properties.debug'
    into 'app/src/main/assets/airshipconfig.properties'
}

assembleDebug {
    dependsOn copyDebugConfigFileTask
}

assembleRelease {
    dependsOn copyReleaseConfigFileTask
}

Answer 1

First of all, you didn't properly configured your tasks. You've tried to make CopySpecification configuration in the execution phase, though it has to be done at configuration phase. To achieve this, you have to delete << from your task specification. It has to be rewritten this way:

task copyReleaseConfigFileTask(type: Copy) {
    doLast {
         println "-> using airship release config"
    }
    from 'app/src/main/assets/airshipconfig.properties.release'
    into 'app/src/main/assets'
    rename('airshipconfig.properies.release','airshipconfig.properties')
}

task copyDebugConfigFileTask(type: Copy) {
    doLast {
        println "-> using airship debug config"
    }
    from 'app/src/main/assets/airshipconfig.properties.debug'
    into 'app/src/main/assets'
    rename('airshipconfig.properties.debug','airshipconfig.properties')
}

Note, << is the same as a doLast closure. So, this will properly configure your copy tasks, but the message will appear only after execution.

One more, you've provided an into value as path with file name, but it has to be a path to the directory, not a file. To rename it, use a rename closure additionally. Read about it in the official CopySpec API