Cython-为什么我的循环中的索引分配语句仍然发黄？

Question

I am trying to learn Cython and trying to write a speedy version of a bootstrapping function. My main loop has one pesky statement which is still yellow and I can't figure out why it's yellow. I would really appreciate help, thank you.

import numpy as np
cimport numpy as np
from libc.stdlib cimport rand, RAND_MAX


ctypedef np.float64_t FLOAT_t

cpdef FLOAT_t cython_avg(np.ndarray[FLOAT_t, ndim=1] A):
    cdef double [:] x = A
    cdef double s = 0
    cdef unsigned int N = A.shape[0]
    for i in xrange(N):
        s += x[i]
    return s/N


def confidence_interval_mean(np.ndarray[FLOAT_t, ndim=1] sample,int its,int p):
    cdef int n = len(sample)
    cdef double[:] means = np.zeros(its,dtype=np.float)
    cdef np.ndarray[FLOAT_t, ndim=1] s = np.zeros(n,dtype=np.float)
    for i in xrange(its):
        for j in xrange(n):
            s[j] = sample[<int>(rand()/RAND_MAX * n)]
        means[i] = cython_avg(s)
    return np.percentile(means,[(100-p)/2,(100+p)/2])

The line which is inside the two for loops:

Answer 1

Cython still generates code that checks for zero division:

if (unlikely(RAND_MAX == 0)) {
  PyErr_SetString(PyExc_ZeroDivisionError, "integer division or modulo by zero");
  {__pyx_filename = __pyx_f[0]; __pyx_lineno = 26; __pyx_clineno = __LINE__; goto __pyx_L1_error;}
}

and for index bounds (view BufferIndexError s being raised). This code needs to raise appropriate Python exceptions if that occurs, as such, you have Python interaction. The overhead from this interaction though is not something you should really be concerned about.

If you want to get it completely white and if you are always certain the denominator != 0 and that the loop never tries to access an element that is out of bounds, you can add the appropriate compiler directives ( boundscheck and cdivision ) to eliminate these.

cimport them:

from cython cimport cdivision, boundscheck

and decorate (among other ways) your function confidence_interval_mean :

@cdivision
@boundscheck(False)
def confidence_interval_mean(np.ndarray[FLOAT_t, ndim=1] sample,int its,int p):
    # body stays the same

Now you get no checks and a white line: