在Excel中将5列合并为一列

Question

I want to merge 5 columns into a single one like this:

1  4  7  10 13
2  5  8  11 14
3  6  9  12 15

to this

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15

I have this formula and I'm trying to adapt it, but it fails :(

=IF(ROW()<=COUNTA(A:A),INDEX(A:A,ROW()),IF(ROW()<=COUNTA(A:B),INDEX(B:B,ROW()-COUNTA(A:A)),IF(ROW()>COUNTA(A:C),"",INDEX(C:C,ROW()-COUNTA(A:B)))))

The statement uses 3 IF functions, because it needs to combine 3 columns:

1. For column A, the function compares the row number of a cell with the total number of cells in A column that are not empty. If the result is true, the function returns the value of the cell from column A that is at row(). If the result is false, the function moves on to the next IF statement.
2. For column B, the function compares the row number of a cell with the total number of cells in A:B range that are not empty. If the result is true, the function returns the value of the first cell that is not empty in column B. If false, the function moves on to the next IF statement.
3. For column C, the function compares the row number of a cell with the total number of cells in A:C range that are not empty. If the result is true, the function returns a blank cell and doesn't do any more calculation. If false, the function returns the value of the first cell that is not empty in column C.

Do you have any ideas?

Answer 1

You can use the following formula, so long as your results are not in the same row or column as the original data (and could be on another worksheet). In addition, the formula would fail if there are empty cells in the first row or first column.

=IFERROR(INDEX($A$1:$E$3,MOD(ROWS($1:1)-1,COUNTA($A:$A))+1,INT((ROWS($1:1)-1)/COUNTA($A:$A))+1),"")

The row argument and the column argument for the INDEX function, if you tease it apart, you will see that they return the proper sequence of arguments. However, you can add any number of columns or rows to the array.

If you want to define the array as being arbitrarily large, so if your real array can expand without having to change the formula, then, on another worksheet, (eg Sheet2), where myArtray is, for example, Sheet1!$A$1:$Z$100 , try:

=IFERROR(IF(INDEX(myArray,MOD(ROWS($1:1)-1,COUNTA(Sheet1!$A:$A))+1,INT((ROWS($1:1)-1)/COUNTA(Sheet1!$A:$A))+1)="","",
INDEX(myArray,MOD(ROWS($1:1)-1,COUNTA(Sheet1!$A:$A))+1,INT((ROWS($1:1)-1)/COUNTA(Sheet1!$A:$A))+1)),"")

Answer 2

I have tested your formula and it works as expected, it may be though that you are placing your formula within one of the columns that you reference in your formula which will create a circular reference.

In other words, try using your formula in a column that isn't A, B or C and see what happens.

Side note: For what you are trying to achieve I would recommend trying to produce a VBA macro instead, your formula could get quite long and fiddly as you add more and more columns where as a simple macro would let you do something like this with any number of columns.

Answer 3

You can paste this in a code module

Public Function OneDimensionalRange(source As Range)
    Dim index As Integer
    index = Application.Caller.Row
    OneDimensionalRange = source.Cells(index).value
End Function

It'll be available for use as a worksheet function.

=OneDimensionalRange($A$3:$E$3)

Answer 4

这是我需要的直到S的要求公式。

=IF(ROW()<=COUNTA(A:A),INDEX(A:A,ROW()),IF(ROW()<=COUNTA(A:B),INDEX(B:B,ROW()-COUNTA(A:A)),IF(ROW()<=COUNTA(A:C),INDEX(C:C,ROW()-COUNTA(A:B)),IF(ROW()<=COUNTA(A:D),INDEX(D:D,ROW()-COUNTA(A:C)),IF(ROW()<=COUNTA(A:E),INDEX(E:E,ROW()-COUNTA(A:D)),IF(ROW()<=COUNTA(A:F),INDEX(F:F,ROW()-COUNTA(A:E)),IF(ROW()<=COUNTA(A:G),INDEX(G:G,ROW()-COUNTA(A:F)),IF(ROW()<=COUNTA(A:H),INDEX(H:H,ROW()-COUNTA(A:G)),IF(ROW()<=COUNTA(A:I),INDEX(I:I,ROW()-COUNTA(A:H)),IF(ROW()<=COUNTA(A:J),INDEX(J:J,ROW()-COUNTA(A:I)),IF(ROW()<=COUNTA(A:K),INDEX(K:K,ROW()-COUNTA(A:J)),IF(ROW()<=COUNTA(A:L),INDEX(L:L,ROW()-COUNTA(A:K)),IF(ROW()<=COUNTA(A:M),INDEX(M:M,ROW()-COUNTA(A:L)),IF(ROW()<=COUNTA(A:N),INDEX(N:N,ROW()-COUNTA(A:M)),IF(ROW()<=COUNTA(A:O),INDEX(O:O,ROW()-COUNTA(A:N)),IF(ROW()<=COUNTA(A:P),INDEX(P:P,ROW()-COUNTA(A:O)),IF(ROW()<=COUNTA(A:Q),INDEX(Q:Q,ROW()-COUNTA(A:P)),IF(ROW()<=COUNTA(A:R),INDEX(R:R,ROW()-COUNTA(A:Q)),IF(ROW()>COUNTA(A:S),"",INDEX(S:S,ROW()-COUNTA(A:R)))))))))))))))))))))