如何从Excel工作表调用VBA函数

Question

Whenever I try to call the function from a cell by typing =MAE() it won't run, always returns a 0. Can someone help guide me? The function below works fine as a sub procedure. It needs to loop through an entire column and calculate the absolute average

Function MAE() As Double
    Dim cell As Object
    Dim nRows As Integer
    Dim total As Double
    Dim i As Integer
    Dim mean As Double
    total = 0

    ' Count the rows
    With wsData.Range("A2")
        nRows = Range(.Offset(0, 0), .End(xlDown)).Rows.Count
    End With
    'loop through rows, add to total, select next cell
    Range("A2").Select
    For i = 0 To nRows
        total = total + Abs(ActiveCell.Value)
        ActiveCell.Offset(1, 0).Select
    Next i

    MAE = total / (nRows)
End Function

Answer 1

I would avoid selecting the cells when looping through them.
With the following code it works for me:

...
' Count the rows
With ActiveSheet.Range("A2")
    nRows = Range(.Offset(0, 0), .End(xlDown)).Rows.Count
End With

'loop through rows, add to total, select next cell
For i = 0 To nRows
    total = total + Abs(ActiveSheet.Range("A2").Offset(i, 0).Value)
Next i

...

Answer 2

You rarely have to select or activate cells. Never select or activate from a UDF.

Use Application.Volatile so that your function will recalculate as values change.

Function MAE() As Double
    Dim cell As Object
    Dim rCells As Range
    Application.Volatile
    With wsData.Range("A2")
        Set rCells = Range(.Offset(0, 0), .End(xlDown))
        For Each cell In rCells
            total = total + Abs(cell.value)
        Next cell
    End With

    MAE = total / rCells.Count
End Function

This might be more useful.

MAE(A2:A7)

Function MAE(rCells As Range) As Double
    Dim cell As Object

    Application.Volatile

    For Each cell In rCells
        total = total + Abs(cell.value)
    Next cell

    MAE = total / rCells.Count
End Function