在Linux中解析

Question

I want to parse the compute zones in open-stack command output as below

+-----------------------+----------------------------------------+
| Name                  | Status                                 |
+-----------------------+----------------------------------------+
| internal              | available                              |
| |- controller         |                                        |
| | |- nova-conductor   | enabled :-) 2016-07-07T08:09:57.000000 |
| | |- nova-consoleauth | enabled :-) 2016-07-07T08:10:01.000000 |
| | |- nova-scheduler   | enabled :-) 2016-07-07T08:10:00.000000 |
| | |- nova-cert        | enabled :-) 2016-07-07T08:10:00.000000 |
| Compute01             | available                              |
| |- compute01          |                                        |
| | |- nova-compute     | enabled :-) 2016-07-07T08:09:53.000000 |
| Compute02             | available                              |
| |- compute02          |                                        |
| | |- nova-compute     | enabled :-) 2016-07-07T08:10:00.000000 |
| nova                  | not available                          |
+-----------------------+----------------------------------------+

i want to parse the result as below, taking only nodes having nova-compute

Compute01;Compute02

I used below command:

nova availability-zone-list | awk 'NR>2 {print $2}' | grep -v '|' | tr '\n' ';'

but it returns output like this

;internal;Compute01;Compute02;nova;;

Answer 1

In Perl (and written rather more verbosely than is really necessary):

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

my $node; # Store current node name
my @compute_nodes; # Store known nova-compute nodes

while (<>) { # Read from STDIN
  # If we find the start of line, followed by a pipe, a space and
  # a series of word characters...
  if (/^\| (\w+)/) {
    # Store the series of word characters (i.e. the node name) in $node
    $node = $1;
  }

  # If we find a line that contains "nova-compute", add the current
  # node name in @compute_nodes
  push @compute_nodes, $node if /nova-compute/;
}

# Print out all of the values in @compute_nodes    
say join ';', @compute_nodes;

Answer 2

I detest one-line programs except for the most simple of applications. They are unnecessarily cryptic, they have none of the usual programming support, and they are stored only in the terminal buffer. Want to do the same thing tomorrow? You must start coding again

Here's a Perl solution. Run it as

$ perl nova-compute.pl command-output.txt

use strict;
use warnings 'all';

my ($node, @nodes);

while ( <> ) {
    $node = $1 if /^ \| \s* (\w+) /x;
    push @nodes, $node if /nova-compute/;
}

print join(';', @nodes), "\n";

output

Compute01;Compute02

Now all of that is saved on disk. It may be run again at any time, modified for similar results, or fixed if you got it wrong. It is also readable. No contest

Answer 3

$  nova availability-zone-list | awk '/^[|] [^|]/{node=$2} node && /nova-compute/ {s=s ";" node} END{print substr(s,2)}' 
Compute01;Compute02

How it works:

• /^[|] [^|]/{node=$2}

  Any time a line begins with | followed by space followed by a character not | , then save the second field as a node name.

• node && /nova-compute/ {s=s ";" node}

  If node is non-empty and the current line contains nova-compute , then append node to the string s .

• END{print substr(s,2)}

  After we have read all the lines, print out string s minus its first character which is a superfluous ; .