使用VBA删除工作簿中的第二页和第三页

Question

Im looking to delete second and third sheet in a workbook with hundreds of sheets. So, keep sheets 1,4,7,10... and delete the rest

I'm running into issues because the indices reset with every sheet I delete so looping with i's is presenting a problem.

Any ideas?

Thanks!

Answer 1

RGA is right you should loop from last to first when deleting. Index mod 3 will return 1 for 1, 4, 7, 10 , 13, 16 .ect.

Sub DeleteEvery2ndAnd3rdSheet()
   Application.DisplayAlerts = False

    Dim i As Integer
    For i = Worksheets.Count To 1 Step -1
        If i Mod 3 <> 1 Then Worksheets(i).Delete
    Next

    Application.DisplayAlerts = True

End Sub

Answer 2

While Thomas' answer may be the way to go, here is another approach that will only run the Delete statement once.

Sub Delete2nd3rdSheets()

Dim sSheetsToRemove As String
Dim i As Integer

Dim ws As Worksheet
For Each ws In ThisWorkbook.Worksheets

    If ws.Index Mod 3 <> 1 Then
        sSheetsToRemove = sSheetsToRemove & "," & ws.Name
    End If

Next

sSheetsToRemove = Mid(sSheetsToRemove, 2)

Dim arrDeleteSheets() As String
arrDeleteSheets = Split(sSheetsToRemove, ",")

Application.DisplayAlerts = False
Worksheets(arrDeleteSheets).Delete
Application.DisplayAlerts = True

End Sub

Answer 3

Loop from the end to the beginning instead of beginning to end (always good practice when deleting things from a list in any coding language)

Just keep a counter running as you go that counts up to three and resets, making sure first that it is set properly to act on the last sheet (aka figure out with math whether that last sheet would be a "1st", "2nd", or "3rd" sheet)