Excel VBA反向进度栏

Question

I am using a progress bar to show the user the status of a running macro, however because the macro deletes rows it is running backwards For i = lastrow To 2 Step -1 , meaning that my progress bar is running from 100% down to 2%.

I have only ever counted up with i , is it possible to make the progress read the info backwards when counting down, so to the user it visibly is counting up?

Sub update()
Dim lastRow As Integer, email As String, pctCompl As Single

lastRow = Sheets("Sheet1").Range("C5000").End(xlUp).Row

For i = lastRow To 2 Step -1
    email = Trim(Cells(i, 3).Value)
    Set c = Sheets("Sheet3").Range("A:A").Find(email, LookIn:=xlValues)
    If Not c Is Nothing Then
        Cells(i, 1).EntireRow.Delete
    End If
    pctCompl = i
    progress pctCompl
Next i

End Sub

Sub progress(pctCompl As Single)
UserForm1.Text.Caption = pctCompl & "% Completed"
UserForm1.Bar.Width = pctCompl * 2
DoEvents
End Sub

Answer 1

as an out of the box answer you may want to consider this sub:

Sub update()    
    With Worksheets("Sheet1")
        With .Range("C2:C" & .Cells(.Rows.Count, 3).End(xlUp).Row)
            With .offset(, .Parent.UsedRange.Columns.Count)
                .FormulaR1C1 = "=iferror(match(RC3,Sheet3!C1,0),"""")"
                .value = .value
                .SpecialCells(xlCellTypeBlanks).EntireRow.Delete
                .Delete
            End With
        End With
    End With
end Sub

which shouldn't require any progress bar at all...

Answer 2

Replace

progress pctCompl

with

progress Abs(Round(i / lastRow * 100, 0) - 100) + 1

There's no need to set i to a variable called pctCompl - just pass the value to the procedure.