Excel VBA InputBox和MsgBox输出

Question

I am working on a program in which the user will supply the information for the length of a wall in cell D3 and E3 from a InputBox prompt.

Public Sub dimensionInput()

Dim wallWidth As Double 'Get Wall Width Input
wallWidth = Application.InputBox("Input Desired Secondary Containment Wall Width in Inches", "Wall Width", 1)
If wallWidth = False Then
    Exit Sub
Else
Application.Worksheets("Sheet1").Range("D3").Value = wallWidth
End If

Dim wallLen As Variant 'Get Wall Length Input
wallWidth = Application.InputBox("Input Desired Secondary Containment Wall Width in Inches", "Wall Width", 1)
If wallLen = False Then
    Exit Sub
Else
Application.Worksheets("Sheet1").Range("D3").Value = wallWidth
End If

End Sub

Once that is done there will be prompts for the radius, length, orientation, and offset. The values will be enter with a comma and a space eg N1, N2, N3, ... I am having a hard time writing the VBA macro to separate the inputs based on the comma and then enter then in the cells. All the entries should go in the respective column. EG

Rad: 40, 30, 26, 23, 24, 20 <---Input by user

Len: 60, 40, 96, 82, 72, 48 <---Input by user

Orient: H, H, V, V, V, V, H <---Input by user

Offset: 2, 2, 4, 1, 2, 1 <---Input by user

Then according to that VBA it will fill in the cells as shown below.

Any help is greatly appreciated!

Answer 1

why dont u try this:
-Create one auxiliar worksheet with the name "Sheet2"
-Edit ur code with that:

Public Sub dimensionInput()

Dim wallWidth As Double 'Get Wall Width Input
wallWidth = Application.InputBox("Input Desired Secondary Containment Wall Width in Inches", "Wall Width", 1)
If wallWidth = False Then
    Exit Sub
Else
Application.Worksheets("Sheet1").Range("D3").Value = wallWidth
End If

Dim wallLen As Variant 'Get Wall Length Input
wallWidth = Application.InputBox("Input Desired Secondary Containment Wall Width in Inches", "Wall Width", 1)
If wallLen = False Then
    Exit Sub
Else
Application.Worksheets("Sheet1").Range("D3").Value = wallWidth
End If

Dim RAD As Variant 'Get Rad Input
RAD = Application.InputBox("Input Desired RAD", "RAD", 1)
If RAD = False Then
    Exit Sub
Else
Application.Worksheets("Sheet2").Range("A1").Value = RAD
End If

Dim LENN As Variant 'Get Len Input
LENN = Application.InputBox("Input Desired LENN", "LEN", 1)
If LENN = False Then
    Exit Sub
Else
Application.Worksheets("Sheet2").Range("A2").Value = LENN
End If

Dim Orient As Variant 'Get Wall Length Input
Orient = Application.InputBox("Input Desired Orient", "Orient", 1)
If Orient = False Then
    Exit Sub
Else
Application.Worksheets("Sheet2").Range("A3").Value = Orient
End If

Dim Offset As Variant 'Get Wall Length Input
Offset = Application.InputBox("Input Desired Offset", "Offset", 1)
If Offset = False Then
    Exit Sub
Else
Application.Worksheets("Sheet2").Range("A4").Value = Offset
End If

Application.Worksheets("Sheet2").Select
Columns("A:A").Select
Selection.TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, Comma:=True, Space:=True


End Sub

-Make reference from ur original sheet to ur new auxiliar sheet!

sure u can improve the code to create one auxiliar sheet every time, do the tasks, transport the values to ur original sheet and than delete this auxiliar sheet.

Answer 2

Inorder to split the input you can use the Split() function

Split (text_string, delimiter, limit, compare)

For example:

Dim xarray() As String
Dim RAD As Variant 'Get Rad Input
RAD = Application.InputBox("Input Desired RAD", "RAD", 1)
xarray() = Split(RAD, ",")
For i = LBound(xarray) To UBound(xarray)
    Cells(6, i + 1).Value = xarray(i)
Next i

This will insert the values in the 6th row starting from the 1st column. If you want it to start from 3rd column, then

Cells(6, i + 3).Value = xarray(i)

Answer 3

UserInput function is prone to many input and reading errors so that it should be followed by quite a robust input treatment routine

but for a head start you could use TextToColumns() method of Range object to try and take care of some conversions, along with a Replace() function to eliminate spaces:

Option Explicit

Public Sub dimensionInput()
    With Worksheets("InputSheet1")
        GetUserInput .Range("D3"), "Input Desired Secondary Containment Wall Length in Inches", "Wall Width", 1
        GetUserInput .Range("E3"), "Input Desired Secondary Containment Wall Length in Inches", "Wall Length", 1
        GetUserInput .Range("C6"), "Input Desired radii for all tanks in Inches", "Tanks radius", 1
        GetUserInput .Range("C7"), "Input Desired lengths for all tanks in Inches", "Tanks lenghts", 1
        GetUserInput .Range("C9"), "Input Desired orientations for all tanks [H/V]", "Tanks orientations", "H"
        GetUserInput .Range("C10"), "Input Desired offsets for all tanks", "Tanks offsets", 1
    End With
End Sub

Sub GetUserInput(rng As Range, prompt As String, title As String, defVal As Variant)
    With rng
        .Value = Replace(CStr(Application.InputBox(prompt, title, defVal)), " ", "", vbTextCompare)
        If InStr(.Value, ",") > 0 Then .TextToColumns DataType:=xlDelimited, Comma:=True
    End With
End Sub

but still you'll HAVE problems with user inputs, being the "input user" the most bastard and inventive species in the galaxy.