Perl：为变量分配3个可能值之一

Question

I have a DNA sequence. Let's call it "ATCG". I have 2 small databases of DNA sequences in 2 separate files, which we will call "db1.txt" and "db2.txt". Both databases are formatted as follows:

>name of sequence
EXAMPLESEQUENCEATCGATCG
>name of another sequence
ASECONDEXAMPLESEQUENCEATCGATCG

I want to know if my DNA sequence is contained in one of the databases, and if so which one. My result, then, has 3 possible values: my sequence is in neither database, in db1, or in db2. Here's my code:

use warnings;
use strict;
my $entry = 'ATCG';
my $returnval = "The sequence is from neither database";

#if in db1
    my $name1;
    my $seq1;
    open (my $database1, "<", "db1.txt") or die "Can't find db1";
    while (<$database1>){
        chomp ($name1 = <$database1>);
        chomp ($seq1 = <$database1>);
        if (
            index($seq1, $entry) != -1
            || index($entry, $seq1) != -1
        ) {
            $returnval = "The sequence is from db1: ". $name1;
            last;
        }
    }

#If in db2:
    my $name2;
    my $seq2;
    open (my $database2, "<", "db2.txt") or die "Can't find db2";
    while (<$database2>){
        chomp ($name2 = <$database2>);
        chomp ($seq2 = <$database2>);
        if(
            index($seq2, $entry) != -1
            || index($entry, $seq2) != -1
        ) {
            $returnval = "The sequence is from db2: ". $name2;
            last;
        }

    }
    print $returnval . "\n";

There are a few problems with this code (probably more than a few). No matter what my sequence, $returnval = "The sequence is from db2: " with no name at the end. Furthermore, it seems that $name2 and $seq2 are uninitialized values, even though the code is identical to that for db1. If I remove the entire section for testing for db2, the code only returns "the sequence is from db1: " followed by the appropriate name for some sequences I copied and pasted from the database, while it returns "the sequence is from neither database" for others.

What am I doing wrong? How do I fix the uninitialized values, and why is the code for db2 not working?

EDIT: I forgot to mention that outputting that the sequence is in db2 takes precedence over outputting that it is in db1, should a sequence be in both.

Answer 1

The main issue is in the conditions of the while loops, which read and discard a line each iteration and prevent the $name and $seq variables from containing a name and sequence each time. Removing that condition and placing the check for end-of-file inside the loop should fix the problem. It's also possible to loop over the two databases and apply the same logic to both, so you'll only need one loop to examine the contents of each file.

use warnings;
use strict;
my $entry = 'ATCG';
my $returnval = "The sequence is from neither database";
my @files = qw(db2 db1);

FILE:
for my $file (@files) {
    open my $fh, '<', "$file.txt" or die "Error opening $file: $!";
    while (1) {
        my $name = <$fh>;
        my $seq  = <$fh>;
        if (not defined $seq) {
            warn "Odd number of lines in $file" if defined $name;
            last; # Reached end of file
        }
        chomp($name, $seq);
        if (
            index($seq, $entry) != -1
            or index($entry, $seq) != -1
        ) {
            $returnval = "The sequence is from $file: $name";
            last FILE; # No need to search the others
        }
    }
}

print "$returnval\n";

Answer 2

I would wrap the comparison in a subroutine, especially since you have to do the same thing multiple times

This solution implements a subroutine matches , which returns the name of the matching sequence in the file, or a false value if it was not found

I have altered the record separator $/ to the > character so that sequences are split automatically, with each record consisting of the name up to the first newline character, and the sequence thereafter. The tr/\\n//d call removes any newlines from the sequence (so it will handle multi-line sequences as the FAST format supports) and a comparison is made for each sequence

The calling code just uses a for loop to call the subroutine for each file name. The loop exits as soon as a match is found, leaving $name and $file set to the details of the match

The message is built and printed according to whether $name ends up true

use strict;
use warnings 'all';
use feature 'say';

my $entry = 'ATCG';

my ($file, $name);

for $file ( qw/ db2 db1 / ) {
    last if $name = matches($entry, "$file.txt");
}

say $name ?
    "The sequence is from $file: $name" :
    "The sequence is from neither database";


sub matches {
    my ($seq, $file) = @_;

    open my $fh, '<', $file or die qq{Unable to open "$file" for input: $!};

    local $/ = '>';

    while ( <$fh> ) {
        chomp;
        my ($name, $file_seq) = split /\n/, $_, 2;
        $file_seq =~ tr/\n//d;

        return $name if index($file_seq, $seq) >= 0 or index($seq, $file_seq) >= 0;
    }

    return;
}