我如何在fortran的do-loop的每个步骤中读入文本文件的连续行？

Question

I have a dataset of parameter values for 30 species, and I want to run a script that conducts a simulation for each species. The parameter values are currently stored in a .txt file, where each row is a different species, and each column is a different parameter value. What I'd like to do is set up a do-loop that reads in the relevant row of parameter values for each species, runs the simulation script, and writes a .txt file of the output for each species. Unfortunately, I'm new to fortran and having a lot of trouble understanding how to read in consecutive rows from a .txt file in each step of a do loop. I tried making a simplified script to test whether the read step was working:

    PROGRAM DRIVER
    IMPLICIT NONE

    INTEGER :: mm ! I forgot this line in the first version of this question   
    and edited to add it in
    CHARACTER(7) :: species  !! the first column is the species name
    REAL*8    :: leaf_variable   !  The next 3 columns are variable values
    REAL*8    :: stem_variable   !  
    REAL*8    :: root_variable   !  

    OPEN (12, file = "species_parameters.txt") ! open the .txt file

    DO mm = 1,30 ! set up the do loop
        READ (12,*) species, leaf_variable, stem_variable, root_variable
        ! Read in the species-specific parameter values
        WRITE (*,*) species, leaf_variable, stem_variable, root_variable
        ! Print the values on the screen just to show the do loop runs
    ENDDO
    END PROGRAM DRIVER

But when I go to compile, I get the error: At line XX of file XX (unit = 12, file = 'species_parameters.txt') Fortran runtime error: End of file

What am I misunderstanding about opening and reading in this file?

Thanks very much for any help.

EDIT: I think I've narrowed down my problem. My understanding is that read() takes in one row in a .txt file at a time, so that in this example:

    read(7, *) species, leaf_variable, stem_variable, root_variable
    read(7, *) species, leaf_variable, stem_variable, root_variable

The variables should equal the values in the second row of the .txt file. Instead, no matter how many times I put in the read() function, the variable values equal the first row. And, even though there are only 4 columns, I can define as many variables as I want with a read() function:

   read(7, *) species, leaf_variable, stem_variable, root_variable, 
            fake_variable1, fake_variable2, fake_variable3, fake_variable4

where the fake_variable values equal the values in the second row of the .txt file. Am I confused about what read() does, or is there something I need to do to keep my script from reading my entire .txt file as one line?

EDIT #2: The do loop reads line by line correctly now that I've saved my .txt file with Unix encoding using TextWrangler. The original file was saved as a .txt file with Excel. This seems to have solved it, but if anyone has suggestions for a better way to specify the input file format, I'd appreciate it. The first few lines of the input file look like this:

    species1,1.2,6.54,10.9
    species2,1.42,3.5,8.23
    species3,0.85,2.41,4.9 

Answer 1

A run time error is when you have an executable, execute it, and it crashes. A compile time error is when the compiler fails to produce an executable.

This code shouldn't compile, because you have IMPLICIT NONE , but haven't declared the integer mm .

What I'd recommend is to get more information:

program driver
    use iso_fortran_env
    implicit none
    character(len=7) :: species
    real(kind=real64) :: leaf_variable, stem_variable, root_variable
    integer :: u, ioerr
    character(len=120) :: iomsg

    open(newunit=u, file='species_parameters.txt', action='read', status='old', iostat=ioerr, iomsg=iomsg)
    if (ioerr /= 0) then
        print *, "Error opening file"
        print *, trim(iomsg)
        stop 1
    end if
    do
        read(u, *, iostat=ioerr, iomsg=iomsg) species, leaf_variable, stem_variable, root_variable
        if (ioerr /= 0) exit  ! exits the loop
        write(*, *) species, leaf_variable, stem_variable, root_variable
    end do
    print *, trim(iomsg)
    close(u)
end program driver

This will always print the "read past end of file" error, but this is just to check how to program reads anyway.

This should compile, and when you run it, it should give you some information on what is going wrong.